2

我正在使用用户提供的用户/密码测试 FTP 连接。

如果我独立运行单元测试，一切正常。但是如果我尝试一个有序的测试，运行FTP_Test_Sucessful之前FTP_Test_Unsuccessful，FTP_Test_Unsuccessful测试失败：即使我提供了一个错误的密码，FTP连接也是成功的连接成功之后。

Passed          Unit Test   FTP_Test_Unsuccessful       00:00:02.3566157
Passed          Unit Test   FTP_Test_Sucessful          00:00:00.3048244
Failed          Unit Test   FTP_Test_Unsuccessful       00:00:00.2696941
Not Executed    Unit Test   FTP_Test_Sucessful          00:00:00

我如何“重置”FTP 连接，以便FTP_Test_Unsuccessful正确测试连接。

这是我的单元测试：

'''<summary>
'''basic Unsuccessful FTP test
'''</summary>
<TestMethod()>
Public Sub FTP_Test_Unsuccessful()
    _TestSettings.FTPEnabled = True
    _TestSettings.ChangeFTPCredentials("User", "BadPasword")
    Try
        Assert.IsFalse(_TestSettings.TestFtpSettings())

    Catch ex As AssertFailedException
        Throw 

    Catch ex As Net.WebException
        Dim FTPResponse As FtpWebResponse = DirectCast(ex.Response, FtpWebResponse)
        Assert.AreEqual(FtpStatusCode.NotLoggedIn, FTPResponse.StatusCode)

    Catch ex As Exception
        Assert.Fail()
    End Try
End Sub

'''<summary>
'''basic Sucessful FTP test
'''</summary>
<TestMethod()>
Public Sub FTP_Test_Sucessful()
    _TestSettings.FTPEnabled = True
    _TestSettings.ChangeFTPCredentials("User", "GoodPasword")
    Assert.IsTrue(_TestSettings.TestFtpSettings())
End Sub

这是相关代码：

Public Function TestFtpSettings() As Boolean
    Dim FTPConnectionTestedSuccessfully As Boolean = False
    Dim response As FtpWebResponse = GetTestFtpResponse()
    Dim StatusCode As System.Net.FtpStatusCode = response.StatusCode
    response.Close()
    FTPConnectionTestedSuccessfully = (StatusCode = Net.FtpStatusCode.OpeningData)

    Return FTPConnectionTestedSuccessfully
End Function

Private Function GetTestFtpResponse() As FtpWebResponse
    Dim request As FtpWebRequest = GetFTPConnection(WebRequestMethods.Ftp.ListDirectory)
    Dim response As FtpWebResponse = GetFTPResponse(request)

    Return (response)
End Function

Private Function GetFTPConnection(Method As String) As FtpWebRequest
    'Get the object used to communicate with the server.

    Dim FTPAdress As Uri = New Uri(String.Format("ftp://{0}:{1}", _
                                                 Me.FTPServerName, _
                                                 Me.FTPPort))

    Dim request As FtpWebRequest = DirectCast(WebRequest.Create(FTPAdress),  _
                                              FtpWebRequest)

    request.Method = Method
    request.Credentials = New NetworkCredential(Me.FTPUserName,
                                                Me.GetDecryptedPassword)
    Return request
End Function

Public Function GetFTPResponse(request As FtpWebRequest) As FtpWebResponse
    Return DirectCast(request.GetResponse(), FtpWebResponse)
End Function
4

1 回答 1

1

感谢这个关于How to Reuse FtpWebRequest Connection的答案，我刚刚添加request.KeepAlive = False到我的 GetFTPConnection 函数中。并且所有测试都通过了。 

Private Function GetFTPConnection(Method As String) As FtpWebRequest
    'Get the object used to communicate with the server.

    Dim FTPAdress As Uri = New Uri(String.Format("ftp://{0}:{1}", _
                                                 Me.FTPServerName, _
                                                 Me.FTPPort))

    Dim request As FtpWebRequest = DirectCast(WebRequest.Create(FTPAdress),  _
                                              FtpWebRequest)

    request.Method = Method
    request.KeepAlive = False
    request.Credentials = New NetworkCredential(Me.FTPUserName,
                                                Me.GetDecryptedPassword)
    Return request
End Function
于 2013-05-21T14:46:24.677 回答