0

我是 XSLT 的新手，所以我寻求帮助。我有许多 XML 文档，以下是其中的一个代表性示例。文档被划分为<sub-doc(n)>元素，元素进一步被划分为<section>元素。在这些部分中有零个或多个<heading>元素，以及一个或多个<paragraph>元素。我的目标是确保每个部分最多有一个<heading>元素，方法是将那些确实有多个标题的部分分成多个部分，每个部分都有一个标题。完成后，<paragraph>紧跟在 a 之后的元素必须与new<heading>一起进入。例如，请注意，在以下示例中，第一个有两个元素。我需要打破这个<heading><section><section><sub-doc1><heading><section>元素分为两个<section>元素，每个元素都有自己的<heading>和后续<paragraph>元素。 

<document>
 <sub-doc1>
  <section> <!-- This section needs to be split -->
   <heading>Subdoc1 first heading text</heading>
   <paragraph>A lot of text</paragraph>
   <paragraph>Yet more text</paragraph>
   <paragraph>More text</paragraph>
   ...
   <heading>Subdoc1 second heading text</heading>
   <paragraph>Even more text</paragraph>
   <paragraph>Some text</paragraph>
   ...
  </section>
  <section>
   <paragraph>Even more text</paragraph>
   ...
  </section>
 </sub-doc1>
 <sub-doc2>
  <section>
   <heading>Subdoc2, first heading text</heading>
   <paragraph>A lot of text here</paragraph>
   <paragraph>Yet more text here</paragraph>
   <paragraph>Yet more text here</paragraph>
   ...
  </section>
 </sub-doc2>
</document>

也就是说，转换后的文档需要如下所示： 

<document>
 <sub-doc1>
  <section> <!-- This section got split into two sections -->
   <heading>Subdoc1 first heading text</heading>
   <paragraph>A lot of text</paragraph>
   <paragraph>Yet more text</paragraph>
   <paragraph>More text</paragraph>
   ...
  </section>
  <section> <!-- This is a new section -->
   <heading>Subdoc1 second heading text</heading>
   <paragraph>Even more text</paragraph>
   <paragraph>Some text</paragraph>
   ...
  </section>
  <section>
   <paragraph>Even more text</paragraph>
   ...
  </section>
 </sub-doc1>
 <sub-doc2>
  <section>
   <heading>Subdoc2, first heading text</heading>
   <paragraph>A lot of text here</paragraph>
   <paragraph>Yet more text here</paragraph>
   <paragraph>Yet more text here</paragraph>
   ...
  </section>
 </sub-doc2>
</document>

请注意，某些部分根本没有<heading>元素。在这些情况下，这些部分应保持不变。此外，某些部分只有一个<heading>. 这些部分也应该保持不变。文档中的其他所有内容都应保持不变。唯一需要进行的转换是在<section>文档中的任何位置具有多个<heading>.

再说一次，我是 XSLT 的新手，无法理解能够完成任务的 XSL。感谢你的协助。

4

2 回答 2

0

该样式表按照您的要求执行。它使用一个键来选择paragraph与给定标题对应的所有元素。

我显示的输出对应于您的示例输入，其中省略了省略号。

请注意，此解决方案要求 section包含任何heading元素的所有元素都具有一个heading元素作为第一个子元素。即第一个之前没有paragraph元素heading。如果这个假设是错误的，那么样式表将需要一个小的改动。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:strip-space elements="*"/>
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:key name="paragraph-for-heading" match="paragraph" use="generate-id(preceding-sibling::heading[1])"/>

  <xsl:template match="node()">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="section[heading]">
    <xsl:apply-templates select="heading"/>
  </xsl:template>

  <xsl:template match="heading">
    <section>
      <xsl:copy>
        <xsl:apply-templates/>
      </xsl:copy>
      <xsl:apply-templates select="key('paragraph-for-heading', generate-id())"/>
    </section>
  </xsl:template>

</xsl:stylesheet>

输出

<document>
   <sub-doc1>
      <section>
         <heading>Subdoc1 first heading text</heading>
         <paragraph>A lot of text</paragraph>
         <paragraph>Yet more text</paragraph>
         <paragraph>More text</paragraph>
      </section>
      <section>
         <heading>Subdoc1 second heading text</heading>
         <paragraph>Even more text</paragraph>
         <paragraph>Some text</paragraph>
      </section>
      <section>
         <paragraph>Even more text</paragraph>
      </section>
   </sub-doc1>
   <sub-doc2>
      <section>
         <heading>Subdoc2, first heading text</heading>
         <paragraph>A lot of text here</paragraph>
         <paragraph>Yet more text here</paragraph>
         <paragraph>Yet more text here</paragraph>
      </section>
   </sub-doc2>
</document>
于 2013-05-20T04:06:15.303 回答
-1

我能够生成您正在寻找的输出。对我来说，这种类型的处理需要在 XPath 中使用 preceeding-sibling 来获取我正在寻找的组元素，当它们存在于另一组元素之间时。

由于您也有一些没有标题的部分，因此我必须以不同的方式处理这些部分。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
  <xsl:template match="document">
    <document>
      <!-- Select the sub-doc elements and print their names, then process their children -->
      <xsl:for-each select="*">
        <xsl:element name="{local-name(.)}">
          <xsl:for-each select="section">
            <!-- For a section with 1 or more headings -->
            <xsl:choose>
              <xsl:when test="count(heading) &gt; 0">
                <!-- Print each section, heading and the paragraphs that follow -->
                <xsl:for-each select="heading">
                  <xsl:variable name="currentHeading" select="current()"/>
                  <section>
                    <heading>
                      <xsl:value-of select="."/>
                    </heading>
                    <!-- Pick paragraphs that follow current heading -->
                    <xsl:variable name="paragraphList" select="../paragraph[preceding-sibling::heading[1] = $currentHeading]"/>
                    <xsl:for-each select="$paragraphList">
                      <paragraph>
                        <xsl:value-of select="."/>
                      </paragraph>
                    </xsl:for-each>
                  </section>
                </xsl:for-each>
              </xsl:when>
              <xsl:otherwise>
                <section>
                  <xsl:for-each select="paragraph">
                    <paragraph>
                      <xsl:value-of select="."/>
                    </paragraph>
                  </xsl:for-each>
                </section>
              </xsl:otherwise>
            </xsl:choose>
          </xsl:for-each>
        </xsl:element>
      </xsl:for-each>
    </document>
  </xsl:template>
</xsl:stylesheet>

尼拉吉

于 2013-05-20T01:54:54.617 回答