3

我正在尝试将一些 Haskell 代码移植到 F#，但我遇到了一个奇怪的错误，我不知道如何解决。我有一个有区别的联合，其功能定义如下：

type OtherType =
    OtherType1 of string
    | OtherType2 of string
type MyType<'a> = 
    MySub1 of DateTime * string * (float -> MyType<'a>)
    | MySub2 of 'a
    | MySub3 of DateTime * string * (bool -> MyType<'a>)

后来我有一个适用于这种类型的函数

let fun1 date myType (myFun2: ('b -> MyType<'a>)) = 
    match myType with
    | OtherType1(string1) -> MySub1(date, string1, myFun2)
    | OtherType2(string1) -> MySub3(date, string1, myFun2)

然后，这将 myFun2 限制为类型 (float -> MyType<'a>)。有什么办法可以防止这种情况发生并保持 k 通用？

结果是第二个模式匹配失败。

谢谢你。

更新：

查看我试图复制的 Haskell 代码，我认为问题在于，在 Haskell 版本中，OtherType 是 GADT，OtherType1 变为 OtherType Double，OtherType2 变为 OtherType Bool。然后 myFun2 将能够执行这两个功能。如果有人感兴趣，这是代码。

data OtherType a where
    OtherType1 :: String -> OtherType Double
    OtherType2 :: String -> OtherType Bool 

data MyType a = MySub1 UTCTime String (Double -> MyType a)
    | MySub2 a
    | MySub3 UTCTime String (Bool -> MyType a)

myFun1 :: UTCTime -> OtherType a -> MyType a
myFun1 time o = myFun1' o MySub2
    where
        myFun1' :: OtherType b-> (b -> MyType a) -> MyType a
        myFun1' (OtherType1 name) k = MySub1 time name k
        myFun1' (OtherType2 name) k = MySub3 time name k

所以我想要问的问题是，可以在 F# 中复制 GADT 吗？

4

2 回答 2

3

据我所知，在 F# 中没有可靠的方法来表示任意 GADT。但是，鉴于 GADT 的结构和您正在编写的函数，应该可以使用以下（笨拙的）编码：

// Module for witnessing the equality of two types
module Eq =
    // opaque type equating 'a and 'b
    type eq<'a,'b> = private Eq of ('a -> 'b) * ('b -> 'a) with
        member eq.Apply(v) = match eq with | Eq(f,_) -> f v
        member eq.Unapply(v) = match eq with | Eq(_,g) -> g v

    // constructs an eq<'a,'a>
    [<GeneralizableValue>]
    let refl<'a> : eq<'a,'a> = Eq(id,id)

    // Not used, but included for completeness
    let sym (Eq(f,g)) = Eq(g,f)
    let trans (Eq(f,g)) (Eq(h,i)) = Eq(f >> h, i >> g)

    // ideally, we'd also provide a way to lift an eq<'a,'b> to an eq<F<'a>,F<'b>>, but this can't be expressed by F#'s type system

type OtherType<'a> =
| OtherType1 of Eq.eq<'a,double> * string
| OtherType2 of Eq.eq<'a,bool> * string

// "smart" constructors
let otherType1 s = OtherType1(Eq.refl, s)
let otherType2 s = OtherType2(Eq.refl, s)

type MyType<'a> =
| MySub1 of DateTime * string * (float -> MyType<'a>)
| MySub2 of 'a
| MySub3 of DateTime * string * (bool -> MyType<'a>)

let fun1 date myType myFun2 = 
    match myType with
    | OtherType1(eq, string1) -> MySub1(date, string1, eq.Unapply >> myFun2)
    | OtherType2(eq, string1) -> MySub3(date, string1, eq.Unapply >> myFun2)
于 2013-05-20T21:17:10.693 回答
2

我怀疑您想要可以用通用方法模拟的 Rank-2 类型

open System

type OtherType =
    OtherType1 of string
    | OtherType2 of string

type MyType<'a> = 
    MySub1 of DateTime * string * (float -> MyType<'a>)
    | MySub2 of 'a
    | MySub3 of DateTime * string * (bool -> MyType<'a>)

type F<'a> = abstract member Invoke<'b> : 'b -> MyType<'a>

let fun1 date myType (myFun2: F<'a>) = 
    match myType with
    | OtherType1(string1) -> MySub1(date, string1, myFun2.Invoke)
    | OtherType2(string1) -> MySub3(date, string1, myFun2.Invoke)

fun1 DateTime.Now (OtherType1 "a") {
    new F<_> with
        member this.Invoke v = failwith "to be implemented"
    }
于 2013-05-19T22:15:23.017 回答