1

我有一个 csv 文件的导入规范，当我通过 GUI 在文件上运行它时，它工作得很好。但是，当我通过 VBA 运行它时，由于某种原因，它忘记了一列应该是 Text 列，而是将其设为 Number 列，从而导致大量错误。

我的代码如下。它可以正常运行，但由于某种原因，CSV 的导入规范无法正常运行。无意义的案例开关是一个占位符，因为在我第一次工作后我需要添加更多类型的报告。

Sub ImportDE(Folder As Object)
Dim db As DAO.Database
Dim names As DAO.Recordset
Dim Files As Object, file As Object, SubFolders As Object, subfolder As Object
Dim ExString As Variant
Dim check As Boolean
Dim FileChange As String

Set db = CurrentDb
On Error Resume Next:   db.TableDefs.Delete "tblImport":   On Error GoTo 0
db.TableDefs.Refresh

Set names = CurrentDb.OpenRecordset("SELECT Old FROM DENames")

Set Files = Folder.Files
Set SubFolders = Folder.SubFolders

For Each subfolder In SubFolders
    ImportDE subfolder
Next

With names
    Do While Not .EOF
        ExString = .Fields(0)
        For Each file In Files
            If InStr(file.Type, "Worksheet") > 0 Then
                If InStr(file.Path, ExString & ".xls") > 0 Then
                    DoCmd.TransferSpreadsheet _
                        TransferType:=acImport, _
                        SpreadsheetType:=acSpreadsheetTypeExcel9, _
                        TableName:="tblImport_" & ExString, _
                        filename:=file.Path, _
                        HasFieldNames:=True, _
                        Range:="A:CT"
                    db.TableDefs.Refresh
                End If
            ElseIf InStr(file.Type, "Comma Separated") > 0 Then
                If InStr(file.Path, ExString & ".csv") > 0 Then
                    Select Case ExString
                    Case "Usage"
                        DoCmd.TransferText _
                            TransferType:=acImportDelim, _
                            SpecificationName:=UsageCSV, _
                            TableName:="tblImport_" & ExString, _
                            filename:=file.Path, _
                            HasFieldNames:=True
                        db.TableDefs.Refresh
                    End Select
                End If
            End If
        Next
        .MoveNext
    Loop
End With
db.Close:   Set db = Nothing
End Sub

我错过了一些明显的东西吗？为什么导入规范不能正常工作？

4

2 回答 2

2

TransferText SpecificationName参数应该是一个字符串表达式。由于代码没有声明一个名为 的变量UsageCSV，我猜这是规范的字面名称。如果正确，请将名称用双引号括起来。

DoCmd.TransferText _
    TransferType:=acImportDelim, _
    SpecificationName:="UsageCSV", _
    TableName:="tblImport_" & ExString, _
    filename:=file.Path, _
    HasFieldNames:=True
于 2013-05-17T18:57:01.027 回答
2

在选项比较数据库添加选项显式之后的代码模块顶部。这将需要声明所有变量，并且您将永远不会再遇到此问题

于 2015-06-23T19:40:54.690 回答