0

无法为 XSLT 变量重新赋值，或者我可以
<xsl:for-each有条件地退出
我的 XML

<R>
  <A id="a">  
    <S id="a111">1</S>  
    <S id="a222">2</S>
    <S id="a333">3
      <S id="a3331">3.1</S>
      <S id="a3332">3.2</S>
      <S id="a3333">3.3</S>  
    </S>
    <S id="a444">4</S>
    <S id="a555">5</S>
    <S id="a666">6</S>
  </A>
  <A id="x">
    <S id="x111">1</S>
    <S id="x222">2</S>
    <S id="x333">3
      <S id="x3331">3.1</S>
      <S id="x3332">3.2</S>
      <S id="x3333">3.3</S>
    </S>
    <S id="x444">4</S>
    <S id="x555">5</S>
    <S id="x666">6</S>
  </A>
</R>

我的 XSLT

     <select id ="S"  name="SList">
     <option>
       <xsl:attribute name="value"></xsl:attribute> Please Select S 
     </option>
     <xsl:for-each select="A[id='x']//S">

       <xsl:if test="'x3333'= @id">
         <xsl:variable name="currentS" select="true()"/>
       </xsl:if>
       <xsl:if test="'x3333'!= @id">
         <xsl:variable name="currentS" select="false()"/>
       </xsl:if>

       <xsl:if test="@currentS = false()">
         <option>
           <xsl:if test="@id = 'x3333'">
             <xsl:attribute name="selected">selected</xsl:attribute>
           </xsl:if>
           <xsl:attribute name="value">
             <xsl:value-of select="@id"/>
           </xsl:attribute>              
           <xsl:value-of select="Text"/>
         </option>
       </xsl:if>
     </xsl:for-each>

我正在尝试创建一个下拉列表，我需要S在列表中包含项目。我正在传递当前位置（S在本例中为当前位置x3333）和当前 id A。我只想获取S最新A元素中的元素列表。

在这个例子中，由于我当前S的 isx3333和 id of Aisx我只需要x111, x222, x333, x3331,x3332就可以在列表中。这意味着我需要消除这些

  <S id="x444">4</S>,
  <S id="x555">5</S>,
  <S id="x666">6</S>, nodes

从这段代码<xsl:for-each select="A[id='x']//S">

我正在获取S元素列表Awhereid='x'

有人可以建议我一个解决方案吗？

4

2 回答 2

0

在 XSLT 中对变量执行您想要执行的操作的一种方法是在变量的选择中使用 XPath if 语句：

<xsl:variable name="currentS" select=" if (@id = 'x3333') then true() else false()"/>

XPath if 在尝试执行其值应取决于 if-then 构造的变量时非常有用。但这仅在 XPath 2.0 处理器中可用，而且看起来 OP 使用的是 1.0 处理器。这应该有效：

   <xsl:variable name="currentS" select="@id = 'x3333'"/>
于 2013-05-14T12:02:42.593 回答
0

目前还不清楚你试图做什么。
这里给你一些提示xslt：

属性的错误访问： <xsl:for-each select="A[id='x']//S">
要测试属性 id 使用@id：<xsl:for-each select="A[@id='x']//S">
您不能重新定义变量：

<xsl:if test="'x3333'= @id">
        <xsl:variable name="currentS" select="true()"/>
</xsl:if>
<xsl:if test="'x3333'!= @id">
     <xsl:variable name="currentS" select="false()"/>
</xsl:if>

变量 currentS 仅在 xsl:if 的范围内定义。要根据属性 id 设置变量值，请尝试以下操作：

        <xsl:variable name="currentS">
            <xsl:choose>
                <xsl:when test="@id = 'x3333'">
                    <xsl:text>true</xsl:text>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:text>false</xsl:text>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

变量值的错误访问： <xsl:if test="@currentS = false()">
xslt 变量访问是通过 wint$前缀完成的。

<xsl:if test="$currentS = 'false'">

根据我对您的 xlst 的解释，这可能会有所帮助：

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
    <xsl:template match="R">

        <select id ="S"  name="SList">
            <option>
                <xsl:attribute name="value"></xsl:attribute> Please Select S
            </option>
            <xsl:for-each select="A[@id='x']//S">
                <xsl:variable name="currentS">
                <xsl:choose>
                    <xsl:when test="preceding::S[@id = 'x3333']">
                        <xsl:text>true</xsl:text>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:text>false</xsl:text>
                    </xsl:otherwise>
                </xsl:choose>

            </xsl:variable>
                <xsl:if test="$currentS = 'false'">
                    <option>
                        <xsl:if test="@id = 'x3333'">
                            <xsl:attribute name="selected">selected</xsl:attribute>
                        </xsl:if>
                        <xsl:attribute name="value">
                            <xsl:value-of select="@id"/>
                        </xsl:attribute>
                        <xsl:value-of select="normalize-space(text())"/>
                    </option>
                </xsl:if>
            </xsl:for-each>
        </select>
    </xsl:template>
</xsl:stylesheet>

生成以下输出：

<?xml version="1.0"?>
<select id="S" name="SList">
    <option value="">
        Please Select S
    </option>
    <option value="x111">1</option>
    <option value="x222">2</option>
    <option value="x333">3</option>
    <option value="x3331">3.1</option>
    <option value="x3332">3.2</option>
    <option selected="selected" value="x3333">3.3</option>
</select>
于 2013-05-14T13:02:03.693 回答