2

假设我有以下我希望压缩的文件名数组

my @files = ("C:\Windows\Perl\test1.txt", "C:\Windows\Perl\test2.txt", "C:\Windows\Perl\test3.txt");

如果我做

$obj = Archive::Zip->new(); 
foreach (@files)
 {
    $obj->addFile($_);   
 }

$obj->writeToFileNamed("zippedFolders.zip");

当我打开 zippedFolders.zip 时，我看到它包含子文件夹，即Windowsand Perl，后者实际上包含test1,test2和test3. 出于某种原因，文件夹本身正在被压缩。

我怎样才能做到只有文件被压缩，而不必单击 Windows 然后 Perl 文件夹来访问压缩文件？

4

1 回答 1

7

如您所见，如果您使用addFile将磁盘文件添加到存档，则Archive::Zip添加与文件最初具有相同路径的存档成员。如果您希望将其存储为不同的东西，那么您可以传递第二个参数，该参数将用作创建的存档成员的名称和路径。

出于您的目的，我建议您使用核心File::Basename模块从文件名中删除路径，并将基本名称作为第二个参数传递。

下面的代码演示。

您需要注意的另一件事是，您不能在 Perl 双引号中使用单反斜杠 - 它们将被视为转义以下字符并简单地消失。您可以在字符串中使用成对的反斜杠，改用单引号，改用正斜杠（Perl 会整理出来），或者如果文件名中没有空格，那么您可以qw()像我在这个程序中一样使用。

use strict;
use warnings;

use Archive::Zip;
use File::Basename 'basename';

my @files = qw/
  C:\Windows\Perl\test1.txt
  C:\Windows\Perl\test2.txt
  C:\Windows\Perl\test3.txt
/;

my $zip = Archive::Zip->new;

foreach my $file (@files) {
  my $member = basename $file;
  printf qq{Adding file "%s" as archive member "%s"\n}, $file, $member;
  $zip->addFile($file, $member);   
}

$zip->writeToFileNamed('zippedFolders.zip');

输出

Adding file "C:\Windows\Perl\test1.txt" as archive member "test1.txt"
Adding file "C:\Windows\Perl\test2.txt" as archive member "test2.txt"
Adding file "C:\Windows\Perl\test3.txt" as archive member "test3.txt"
于 2013-05-13T02:52:56.113 回答