perl - 映射：我们可以使用一些东西来代替条件运算符吗

Question

因此，我了解以下代码的作用及其工作原理，但似乎应该有一种不同的方法来做到这一点：

my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;

有没有一种方法，我们基本上可以说：

my @squares = map { if ($_ > 5) then ($_ * $_) } @numbers;

或者我们是否必须对每个条目都有“规则”，即返回（）？

Answer 1

amon 给了你很多信息，但实际上并没有回答这个问题。相当于

map { $_ > 5 ? ($_ * $_) : () }

使用if而不是条件运算符是

map { if ($_ > 5) { $_ * $_ } else { () } }

map 表达式不可能不返回值。它返回最后评估的表达式。如果您删除该else子句，该表达式就是比较，所以它类似于如果您这样做

map { if ($_ > 5) { $_ * $_ } else { $_ > 5 } }

虽然$_ > 5只执行一次，所以我想它更接近

map { ($_ > 5) && ($_ * $_) }

所以，是的，你必须为每个条目制定一个规则，从某种意义上说，不可能不这样做。

Answer 2

为此，该map块必须返回不需要的项目的空列表。虽然您可以用 重写代码grep，

my @squares = map { $_**2 } grep { $_ > 5 } @numbers;

这失去了很多优雅。

如果我们不指定else返回值，则if似乎隐式传递了 false 值：

say $_+0 for map{ if($_>5){$_**2} } 3..7;
# 0
# 0
# 0
# 36
# 49

这对我们的目的毫无用处。

但是我们总是可以编写一个过滤映射来返回我们的块的值，或者如果它是 false 则返回空列表：

sub mapgrep (&@) {
  my $cb = shift;
  map { local $_ = $_; $cb->($_) || () } @_;
}

my @squares = mapgrep { $_**2 if $_ > 5 } @numbers;

但是，这依赖于如果不处理此状态，则条件返回条件值的副作用。我看不出这是在哪里明确记录的。

（注意：Perl 没有关键字then）。