2

我有一个作为我的项目的一部分构建并链接到的库。我想提供设施，可以选择在系统范围内安装库（或设置 ${CMAKE_INSTALL_PREFIX} 的任何位置）。否则，默认情况下，项目的最终构建产品将静态链接到库，并安装前者，但库二进制文件保留在构建目录中。

换句话说：

$ make
$ make install

将构建和安装程序，但仅类似于

$ make install.foo

将库安装到 ${CMAKE_INSTALL_PREFIX}，如果需要，首先构建它。

到目前为止，我有类似的东西（从实际脚本中简化，所以可能会有错误）：

INCLUDE_DIRECTORIES( "${CMAKE_CURRENT_LIST_DIR}")
SET (FOO_LIBRARY "foo")

# Following builds library and makes it available to
# be linked other targets within project by:
# TARGET_LINK_LIBRARIES(${progname} ${FOO_LIBRARY})
ADD_LIBRARY(${FOO_LIBRARY}
    foo/foo.cpp # and other sources ...
    )

###########################################################
# Approach #1
# -----------
# Optionally allow users to install it by invoking:
#
#       cmake .. -DINSTALL_FOO="yes"
#
# This works, but it means that users will have to run
# cmake again to switch back and forth between the libary
# installation and non-library installation.
#
OPTION(INSTALL_FOO "Install foo" OFF)
IF (INSTALL_FOO)
    INSTALL(TARGETS ${FOO_LIBRARY} DESTINATION lib/foo)
    SET(FOO_HEADERS foo/foo.h)
    INSTALL(FILES ${FOO_HEADERS} DESTINATION include/foo)
    UNSET(INSTALL_FOO CACHE)
ENDIF()
###########################################################

###########################################################
# Approach #2
# -----------
# Optionally allow users to install it by invoking:
#
#       make install.foo
#
# Unfortunately, this gets installed by "make install",
# which I want to avoid
SET(FOO_INSTALL "install.foo")
ADD_CUSTOM_TARGET(${FOO_INSTALL}
    COMMAND ${CMAKE_COMMAND}
        -D COMPONENT=foo
        -P cmake_install.cmake)
ADD_DEPENDENCIES(${FOO_INSTALL} ${FOO_LIBRARY})
INSTALL(TARGETS ${FOO_LIBRRARY}
    DESTINATION lib/foo COMPONENT foo)
SET(FOO_HEADERS foo/foo.h)
INSTALL(FILES ${FOO_HEADERS}
    DESTINATION include/foo COMPONENT foo)
###########################################################

可以看出，方法#1 的工作，但安装库所需的步骤是：

$ cmake .. -DINSTALL_FOO="yes"
$ make && make install

然后，要回到“正常”构建，用户必须记住在没有“-DINSTALL_FOO”选项的情况下再次运行 cmake，否则该库将在下一次“make install”时安装。

第二种方法在我运行“make install.foo”时有效，但如果我运行“make install”，它也会安装库。我想避免后者。

有人对如何实现这一目标有任何建议吗？

4

2 回答 2

7

您使用方法#2 走在正确的轨道上。您可以使用install命令的开关来欺骗 CMake 避免安装FOO相关文件。OPTIONAL

对于FOO库目标，必须按以下方式修改命令：

SET (FOO_LIBRARY "foo")
ADD_LIBRARY(${FOO_LIBRARY} EXCLUDE_FROM_ALL
    foo/foo.cpp 
    )
INSTALL(TARGETS ${FOO_LIBRARY}
    DESTINATION lib/foo COMPONENT foo OPTIONAL)

EXCLUDE_FROM_ALL添加 以ADD_LIBRARY防止在您运行普通make. FOO_LIBRARY通过添加OPTIONAL开关可以选择安装。

安装FOO_HEADERS选件需要进行以下更改：

SET(FOO_HEADERS foo/foo.h)
SET(BINARY_FOO_HEADERS "")
FOREACH (FOO_HEADER ${FOO_HEADERS})
    ADD_CUSTOM_COMMAND(
        OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${FOO_HEADER}
        COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/${FOO_HEADER} ${CMAKE_CURRENT_BINARY_DIR}/${FOO_HEADER}
        DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${FOO_HEADER})
    LIST (APPEND BINARY_FOO_HEADERS ${CMAKE_CURRENT_BINARY_DIR}/${FOO_HEADER})
ENDFOREACH()
INSTALL(FILES ${BINARY_FOO_HEADERS}
    DESTINATION include/foo COMPONENT foo OPTIONAL)

FOREACH循环设置自定义命令，将逐字FOO_HEADERS复制到相应的二进制目录。该命令不是直接使用当前源目录中的标头，而是INSTALL(FILES ...从二进制目录中获取复制的标头。二进制目录中标头的路径收集在变量中BINARY_FOO_HEADERS。

最后，FOO_INSTALL必须通过以下方式设置目标：

SET(FOO_INSTALL "install.foo")
ADD_CUSTOM_TARGET(${FOO_INSTALL}
    COMMAND ${CMAKE_COMMAND}
        -D COMPONENT=foo
        -P cmake_install.cmake
    DEPENDS ${BINARY_FOO_HEADERS})
ADD_DEPENDENCIES(${FOO_INSTALL} ${FOO_LIBRARY})

自定义FOO_INSTALL添加了依赖BINARY_FOO_HEADERS项以触发头文件的复制。运行时，目标级别的依赖FOO_LIBRARY会触发库的构建make install.foo。

然而，该解决方案具有以下缺点：

  1. 在配置 CMake 时会发出警告Target "foo" has EXCLUDE_FROM_ALL set and will not be built by default but an install rule has been provided for it.CMake 无论如何都会做正确的事情。

  2. 运行make install.foo后续make install命令后，还将安装所有FOO相关文件，因为构建的FOO库和头文件存在于二进制目录中。

于 2013-05-11T17:31:54.110 回答
-1

检查此解决方案是否适合您。

您必须使用与您说要使用的命令不同的命令，但我认为它很好地解决了这个问题。

于 2013-06-19T22:35:02.333 回答