0

我在从父标签及其子标签中获取所有属性时遇到了一些麻烦。这是我的 XML：

<macro name="editor">
        <names variable="editor" delimiter=", ">
            <name and="symbol" delimiter=", "/>
            <label form="short" prefix=" (" text-case="lowercase" suffix=".)" />
       </names>
</macro>

我希望能够从子节点中获取所有属性。我目前有：

<xsl:for-each select="macro">
   <xsl:value-of select="@*" />
   <br />
</xsl:for-each>

我希望结果如何：

编辑

名称编辑器，

名称符号，

标签短（小写。）

4

3 回答 3

1

试试这个来获取所有变量名称和值：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output indent="yes"/>
  <xsl:template match="macro">
    <xsl:for-each select="child::*//@*">
      <xsl:value-of select="concat(name(), ' : ', .)"/>
      <xsl:text>
    </xsl:text>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

输出：

variable : editor
    delimiter : , 
    and : symbol
    delimiter : , 
    form : short
    prefix :  (
    text-case : lowercase
    suffix : .)
于 2013-05-09T12:20:39.043 回答
1

尝试这个：

<?xml version="1.0"?>
<xsl:stylesheet
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   version="1.0">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*" mode="print_attr">
        <xsl:value-of select="."/>
    </xsl:template>
    <xsl:template match="node()" mode="print_attr">
        <xsl:text>&#10;</xsl:text>
        <br/>
        <xsl:value-of select="name()"/>
        <xsl:text> </xsl:text>
        <xsl:apply-templates mode="print_attr" select="@*|*" />
    </xsl:template>

    <xsl:template match="macro">
        <xsl:apply-templates mode="print_attr" select="@*|*"/>
    </xsl:template>

</xsl:stylesheet>

这将生成此输出：

editor
<br/>names editor,
<br/>name symbol,
<br/>label short (lowercase.)
于 2013-05-09T12:38:01.960 回答
1

当这个 XSLT 转换 

<?xml version='1.0'?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:template match="macro">
  <xsl:value-of select="@name"/>
  <xsl:for-each select="child::*">
    <xsl:text disable-output-escaping="yes">&#10;</xsl:text>
    <xsl:value-of select="name(.)"/>
    <xsl:text> </xsl:text>
    <xsl:value-of select="@*" separator=""/>

    <xsl:for-each select="child::*">
      <xsl:text disable-output-escaping="yes">&#10;</xsl:text>
      <xsl:value-of select="name(.)"/>
      <xsl:text> </xsl:text>
      <xsl:value-of select="@*" separator=""/>
    </xsl:for-each>

  </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

在以下 XML 上运行：

<macro name="editor">
        <names variable="editor" delimiter=", ">
            <name and="symbol" delimiter=", "/>
            <label form="short" prefix=" (" text-case="lowercase" suffix=".)" />
       </names>
</macro>

给出所需的输出：

editor
names editor, 
name symbol, 
label short (lowercase.)
于 2013-05-09T12:36:36.590 回答