windows - Windows批处理-将x数量的文件夹+内容移动到另一个文件夹

Question

我正在清理和整理我的 NAS 文件夹。

但是，我的文件夹中有超过 1800 个文件夹，我需要将其拆分为 18 个文件夹，每个文件夹最多包含 100 个文件夹。他们移动到的文件夹的名称无关紧要，但在顶层应该是连续的。所有文件夹内容都应该一起移动。

此外，我需要一个批处理文件，它也可以逆转这一点。

需要这样做的原因是由于我用来索引和组织我的文件夹和文件夹内容的程序无法轻松处理超过 100 个文件夹的文件夹。

我已经试过了，但最终完全把它搞砸了。

Answer 1

像这样的东西？

@ECHO OFF

SET destination=c:\temp\
SET source=c:\windows\system32\
SET dcount=0
SET fcount=0
SETLOCAL ENABLEDELAYEDEXPANSION

MKDIR %destination%dir%dcount%


FOR /f "tokens=*" %%f in ('DIR /b /s /a:d "%source%*"') do (
  SET str=%%f
  SET str=!str:%source%=!
  MKDIR %destination%dir!dcount!\!str!
  COPY %%f %destination%dir!dcount!\!str! 1> NUL
  SET /a fcount=!fcount!+1
  IF !fcount! EQU 100 (
    SET fcount=0
    SET /a dcount=!dcount!+1
    MKDIR %destination%dir!dcount!
  )
)

ECHO DONE.

显然源和目标需要更改，并且不会尝试进行完整性检查或因错误而优雅地失败......

编辑 ：

第一个版本递归地下降所有子目录并将每个子目录移动到新结构中——基本上破坏了它们的内部嵌套和组织。第二个保留了嵌套在源目录的直接子目录中的子目录的内部结构......选择吧。

@ECHO OFF

SET destination=c:\temp\
SET source=c:\windows\system32\
SET dcount=0
SET fcount=0
SETLOCAL ENABLEDELAYEDEXPANSION

MKDIR %destination%dir%dcount%


FOR /f "tokens=*" %%f in ('DIR /b /a:d "%source%*"') do (
  MKDIR %destination%dir!dcount!\%%f
  XCOPY %source%%%f %destination%dir!dcount!\%%f /e /y 
  SET /a fcount=!fcount!+1
  IF !fcount! EQU 100 (
    SET fcount=0
    SET /a dcount=!dcount!+1
    MKDIR %destination%dir!dcount!
  )
)

ECHO DONE.

Answer 2

这适用于我的有限测试并创建一个UNDO.BAT将文件夹恢复到它们所在的位置。自己测试它，以确保它符合您的要求。

该值num是您想要在每个顶级文件夹中的文件夹数

f用于创建保存文件夹 - 001、002、003 等

在包含要移动的所有子目录的文件夹中启动它。

@echo off
setlocal enabledelayedexpansion
set num=100
set c=0
set f=1001
set folder=%f:~-3%
del undo.bat 2>nul
for /f "delims=" %%a in ('dir /a:d /o:n /b') do (
set /a c=c+1
   md !folder! 2>nul
   move "%%a" !folder!
   echo move "!folder!\%%a" "%cd%" ^& rd !folder! 2^>nul >>undo.bat
    if !c! EQU %num% (
      set c=0
      set /a f=f+1
      set folder=!f:~-3!
    )
)