xslt - 如何使用 XSLT 将 base64 编码的文本加载到 XML 文档中？

Question

如何使用 XSLT 将 base64 编码文本加载到 XML 文档中？

例如，如果我有以下两个文件

输入文件1：

YTM0NZomIzI2OTsmIzM0NTueYQ==

输入文件2：

<xml>
<Column1></Column1>
</xml>

所需的输出：

<xml>
<Column1>YTM0NZomIzI2OTsmIzM0NTueYQ==</Column1>
</xml>

Answer 1

如果您使用的是XSLT 2.0，则可以使用该unparsed-text()函数从文本文件中加载 base64 内容。

在下面的示例中，xsl:param为文档 URI 设置了默认值，但在调用转换时可以设置不同的值。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output indent="yes"/>

    <xsl:param name="base64-document" select="'base64-content.txt'"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Column1">
          <xsl:copy>
            <xsl:value-of select="unparsed-text($base64-document)"/>
          </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

如果您不能使用 XSLT 2.0，那么在XSLT 1.0中，您可以使用带有对 base64 文本文件的实体引用的第三个 XML 文件，以将其内容包含在第三个 XML 文件中。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Column1">
      <xsl:copy>
        <xsl:value-of select="document('thirdFile.xml')/*"/>
      </xsl:copy>
</xsl:template>

</xsl:stylesheet>

您还可以读取 base64 文本文件的内容（在 XSLT 的上下文之外）并将内容作为 an 的值发送xsl:param：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>

<xsl:param name="base64-content" />

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Column1">
      <xsl:copy>
        <xsl:value-of select="$base64-content"/>
      </xsl:copy>
</xsl:template>

</xsl:stylesheet>