1


我需要使用一些 xslt，我不知道从哪里开始，希望你们至少能给我一些线索。

源代码

<ROW>
    <DEPT> A </DEPT>
</ROW>
<ROW>
    <DEPT> B </DEPT>
</ROW>
<ROW>
    <DEPT> A </DEPT>
</ROW>

目标 xml

<DEPTARTMENT>
    <ROW>
        <DEPT> A </DEPT>
    </ROW>
    <ROW>
        <DEPT> A </DEPT>
    </ROW>
</DEPARTMENT>
<DEPTARTMENT>
    <ROW>
        <DEPT> B </DEPT>
    </ROW>
</DEPARTMENT>

感谢您的任何建议。

4

1 回答 1

3

这是一个可能的 XSLT 1.0 解决方案。

当这个 XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="kRowByDept" match="ROW" use="DEPT"/>

  <xsl:template match="/*">
    <T>
      <xsl:apply-templates
        select="ROW[generate-id() = generate-id(key('kRowByDept', DEPT)[1])]"/>
    </T>
  </xsl:template>

  <xsl:template match="ROW">
    <DEPARTMENT>
      <xsl:copy-of select="key('kRowByDept', DEPT)"/>
    </DEPARTMENT>
  </xsl:template>
</xsl:stylesheet>

...应用于提供的 XML（包装在顶级元素中以使文档格式正确）：

<T>
  <ROW>
    <DEPT> A </DEPT>
  </ROW>
  <ROW>
    <DEPT> B </DEPT>
  </ROW>
  <ROW>
    <DEPT> A </DEPT>
  </ROW>
</T>

...产生了所需的解决方案：

<T>
  <DEPARTMENT>
    <ROW>
      <DEPT> A </DEPT>
    </ROW>
    <ROW>
      <DEPT> A </DEPT>
    </ROW>
  </DEPARTMENT>
  <DEPARTMENT>
    <ROW>
      <DEPT> B </DEPT>
    </ROW>
  </DEPARTMENT>
</T>

解释：

这是一个使用Muenchian Grouping的解决方案，这是一种用于将元素分组在一起的 XSLT 1.0 特定方法。

这是一个类似的 XSLT 2.0 解决方案；请注意，它要简单得多。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/*">
    <T>
      <xsl:for-each-group select="ROW" group-by="DEPT">
        <DEPARTMENT>
          <xsl:copy-of select="current-group()" />
        </DEPARTMENT>
      </xsl:for-each-group>
    </T>
  </xsl:template>

</xsl:stylesheet>
于 2013-05-07T14:15:38.053 回答