perl - 从实际文件句柄访问 Perl 的空角“<>”运算符？

Question

我喜欢使用漂亮的 perl 功能，从空角度运算符中读取<>神奇地为您的程序提供 UNIX 过滤器语义，但我希望能够通过实际的文件句柄（或IO::Handle对象或类似对象）访问此功能，这样我就可以做一些事情，比如将它传递给子程序等。有没有办法做到这一点？

这个问题对谷歌来说特别难，因为搜索“角度运算符”和“文件句柄”只是告诉我如何使用角度运算符从文件句柄中读取。

Answer 1

来自perldoc perlvar：

• ARGV

遍历命令行文件名的特殊文件句柄@ARGV. 通常写为角度运算符中的空文件句柄<>。注意目前只在算子ARGV内部有它的神奇效果；<>在其他地方，它只是一个普通文件句柄，对应于<>. 特别是，\*ARGV作为参数传递给需要文件句柄的函数可能不会导致您的函数自动读取@ARGV.

我相信这会以“讨厌说出来，但它不会做你想做的事”的方式回答你问题的所有方面。您可以做的是制作需要打开文件名列表的函数，然后执行以下操作：

sub takes_filenames (@) {
  local @ARGV = @_;
  // do stuff with <>
}

但这可能是你能做到的最好的。

Answer 2

扩展 Chris Lutz 的想法，这是一个非常基本的实现：

#!/usr/bin/perl

package My::ARGV::Reader;

use strict; use warnings;
use autodie;
use IO::Handle;

use overload
    '<>' => \&reader,
    '""' => \&argv,
    '0+' => \&input_line_number,
;

sub new {
    my $class = shift;
    my $self = {
        names => [ @_ ],
        handles => [],
        current_file => 0,
    };
    bless $self => $class;
}

sub reader {
    my $self = shift;

    return scalar <STDIN> unless @{ $self->{names}};

    my $line;

    while ( 1 ) {
        my $current = $self->{current_file};
        return if $current >= @{ $self->{names} };

        my $fh = $self->{handles}->[$current];

        unless ( $fh ) {
            $self->{handles}->[$current] = $fh = $self->open_file;
        }

        if( eof $fh ) {
            close $fh;
            $self->{current_file} = $current + 1;
            next;
        }

        $line = <$fh>;
        last;
    }
    return $line;
}

sub open_file {
    my $self = shift;
    my $name = $self->{names}->[ $self->{current_file} ];
    open my $fh, '<', $name;
    return $fh;
}

sub argv {
    my $self = shift;
    my $name = @{$self->{names}}
             ? $self->{names}->[ $self->{current_file} ]
             : '-'
             ;
    return $name;
}

sub input_line_number {
    my $self = shift;
    my $fh = @{$self->{names}}
           ? $self->{handles}->[$self->{current_file}]
           : \*STDIN
           ;
    return $fh->input_line_number;
}

可以用作：

package main;

use strict; use warnings;

my $it = My::ARGV::Reader->new(@ARGV);

echo($it);

sub echo {
    my ($it) = @_;
    printf "[%s:%d]:%s", $it, +$it, $_ while <$it>;
}

输出：

[文件1：1]：再见
[文件1：2]：你好
[文件1:3]：谢谢
[file1:4]：没有翻译
[文件1：5]：
[文件2：1]：超
[文件2：2]：你好
[文件2:3]：格拉西亚斯
[文件2：4]：

Answer 3

看起来这已经被实现为Iterator::Diamond. Iterator::Diamond 还禁用了 perl 在读取时使用的 2-argument-open 魔法<ARGV>。更好的是，它支持读取'-'为 STDIN，而无需启用所有其他魔法。事实上，我可能只在单个文件上使用它。