11

我有一个 UTF-8 格式的 INI 文件。

我正在使用 Delphi 2010 读取 INI 文件并使用 INI 文件中的值填充 TStringGrid。

var
  ctr : Integer;
  AppIni : TIniFile;
begin
  AppIni := TIniFile.Create(ExtractFilePath(Application.ExeName) + 'test.ini');
    for ctr := 1 to StringGrid1.RowCount do begin
        StringGrid1.Cells[0,ctr] := AppIni.ReadString('Column1','Row'+IntToStr(ctr),'');
        StringGrid1.Cells[1,ctr] := AppIni.ReadString('Column2','Row'+IntToStr(ctr),'');
    end;
  AppIni.Free;

问题是 unicode 字符出现在 TStringGrid 中，显示 2 个字符，而不是 1 个 unicode 字符。

我该如何解决这个问题？

4

3 回答 3

16

该类TIniFile是用于 INI 文件的 Windows API 的包装器。这确实支持 Unicode INI 文件，但前提是这些文件被编码为 UTF-16。Michael Kaplan 在这里有更多细节：Unicode INI 函数；Unicode INI 文件？

所以，你运气不好TIniFile。相反，您可以使用TMemIniFilewhich 允许您在其构造函数中指定编码。该类TMemIniFile是 INI 文件支持的原生 Delphi 实现。两个班级之间有各种利弊。在您的情况下，只能TMemIniFile满足您的需求，因此看起来它的优点将超过其缺点。

于 2013-05-03T18:07:01.063 回答
3 
Uses IniFiles;

const
  SZ_APP_NAME = 'demo_test';

Procedure TForm1.GetSettings;
var
  _MemIniU: TMemIniFile;
  _SettingsPath: string;
begin
  try
    _SettingsPath := GetHomePath + PathDelim + SZ_APP_NAME + PathDelim;
    if ForceDirectories(_SettingsPath) then
    begin
      _MemIniU := TMemIniFile.Create(ChangeFileExt(_SettingsPath,
        'Settings.ini'), TEncoding.UTF8);
      try
        if _MemIniU.ReadInteger(SZ_APP_NAME, 'WindowLeft', -1) = -1 then
          Form1.Position := poScreenCenter
        else
        begin
          Form1.Left := _MemIniU.ReadInteger(SZ_APP_NAME, 'WindowLeft', 10);
          Form1.Top := _MemIniU.ReadInteger(SZ_APP_NAME, 'WindowTop', 10);
          Form1.Width := _MemIniU.ReadInteger(SZ_APP_NAME, 'WindowWidth', 594);
          Form1.Height := _MemIniU.ReadInteger(SZ_APP_NAME,
            'WindowHeight', 342);
        end;
          Edit1.Text := _MemIniU.ReadString(SZ_APP_NAME, 'UnicodeText', 'ąčę');
      finally
        _MemIniU.Free;
      end;
    end;
  except
    on E: Exception do
      MessageDlg(PWideChar(E.Message), TMsgDlgType.mtError,
        [TMsgDlgBtn.mbOK], 0);
  end;
end;

Procedure TForm1.SaveSettings;
var
  _MemIniU: TMemIniFile;
  _SettingsPath: string;
begin
  try
    _SettingsPath := GetHomePath + PathDelim + SZ_APP_NAME + PathDelim;
    _MemIniU := TMemIniFile.Create(ChangeFileExt(_SettingsPath, 'Settings.ini'),
      TEncoding.UTF8);
    try
      if Form1.WindowState <> TWindowState.wsMaximized then
      begin
        _MemIniU.WriteInteger(SZ_APP_NAME, 'WindowLeft', Form1.Left);
        _MemIniU.WriteInteger(SZ_APP_NAME, 'WindowTop', Form1.Top);
        _MemIniU.WriteInteger(SZ_APP_NAME, 'WindowWidth', Form1.Width);
        _MemIniU.WriteInteger(SZ_APP_NAME, 'WindowHeight', Form1.Height);
        _MemIniU.WriteString(SZ_APP_NAME, 'UnicodeText', Edit1.Text);
      end;
      _MemIniU.UpdateFile;
    finally
      _MemIniU.Free;
    end;
  except
    on E: Exception do
      MessageDlg(PWideChar(E.Message), TMsgDlgType.mtError,
        [TMsgDlgBtn.mbOK], 0);
  end;
end;
于 2014-01-30T05:02:19.883 回答
0

在我使用的应用程序中，我TIniFile需要开始存储 Unicode 字符。

为此，我只需在构造函数中将变量类型从TIniFiletoTMemIniFile和 in 更改为在文件名之后添加了第二个参数TEncoding.UTF8。然后在释放我调用的对象之前UpdateFile。如果打开 Ini 文件进行读取，UpdateFile则不需要调用 to。

// ANSI version
var myIniFile: TIniFile;
begin
  myIniFIle := TIniFile.Create('c:\Temp\MyFile.ini');
  myIniFile.WriteString(par1,par2,par3);
  // [...]
  myIniFile.Free;
end


// Unicode version
//1) "Mem" added here
var myIniFile: TMemIniFile; 
begin
  // 2) Enconding added
  myIniFIle := TIniFile.Create('c:\Temp\MyFile.ini', TEncoding.UTF8); 
  myIniFile.WriteString(par1,par2,par3);
  // [...]
  // 3) call to UpdateFile to save to disc the changes
  myIniFile.UpdateFile; 
  myIniFile.Free;
end

好消息是，这UpdateFile会导致 ini 文件以正确的编码保存，这意味着如果一个 ini 文件编码ANSI已经存在，它会被覆盖，所以它变成，所以和UTF-8之间的事务是顺利的，一点也不痛苦。ANSIUTF-8

于 2019-07-22T12:51:56.487 回答