xslt - 使用 XSLT 的两列表

Question

这是我正在处理的 XML 数据的一部分

<?xml version="1.0" encoding="utf-16"?>
<ScorecardSummary>
  <DivisionSummary>
    <DivisionName>
      <string> SYSTEM</string>
    </DivisionName>
    <ScorecardSummaryByDivision>
      <ScorecardSummaryByKPI>
        <Header>
          <string>Committed Time of Arrival</string>
          <string>Goal</string>
          <string>1D</string>
          <string>7D</string>
          <string>QTD</string>
          <string>YTD</string>
          <string>YTD Event Cars</string>
        </Header>
        <Data>
          <ScorecardContract>
            <TypeName>System</TypeName>
            <Goal>68</Goal>
            <GoalWarning>64.6</GoalWarning>
            <TotalCountYear>1234</TotalCountYear>
            <Value1D>79</Value1D>
            <Value7D>79.2</Value7D>
            <ValueQTD>79.1</ValueQTD>
            <ValueYTD>73.3</ValueYTD>
          </ScorecardContract>
          <ScorecardContract>
            <TypeName>AG</TypeName>
            <Goal>68</Goal>
            <GoalWarning>64.6</GoalWarning>
            <TotalCountYear>1111</TotalCountYear>
            <Value1D>80.9</Value1D>
            <Value7D>78.7</Value7D>
            <ValueQTD>78.4</ValueQTD>
            <ValueYTD>69.7</ValueYTD>
          </ScorecardContract>

这是生成表格的 XSL 的一小部分：

<xsl:template match="ScorecardSummary/DivisionSummary/DivisionName">
  <h1>
    <xsl:value-of select="current()/string"/>
  </h1>
</xsl:template>

<xsl:template match="ScorecardSummaryByDivision">
  <xsl:apply-templates select="current()/ScorecardSummaryByKPI"/>
</xsl:template>

<xsl:template match="ScorecardSummaryByKPI">
  <table border="1" cellspacing="0" cellpadding="5">
    <tr>
      <xsl:choose>
        <xsl:when test="count(preceding-sibling::ScorecardSummaryByKPI) mod 6 &lt; 4">
          <td>
            <table border="1" cellspacing="0" cellpadding="5">
              <xsl:apply-templates select="Header"/>
              <xsl:apply-templates select="Data"/>
            </table>
          </td>
        </xsl:when>
        <xsl:otherwise>
          <td>
            <table border="1" cellspacing="0" cellpadding="5">
              <xsl:apply-templates select="Header"/>
              <xsl:apply-templates select="Data"/>
            </table>
          </td>
        </xsl:otherwise>
      </xsl:choose>
    </tr>
  </table>
</xsl:template>

XSL 像这样重复生成 6 个表：

但我想这样订购它们：

等等。我尝试使用此检查，但它不起作用。

count(preceding-sibling::ScorecardSummaryByKPI) mod 6 &lt; 4

任何人都可以帮忙吗？

score 6 · Accepted Answer

解释

您的表格每行必须有两个<td>（如果您想要两列）。您的 XSLT 确实只生成一个。

解决方案是对列表的一半进行迭代，<td>每次迭代生成两个。

所以首先我要定义表格的大小。例子：

  <xsl:param name="size" select="count(catalog/cd)"/>

然后只迭代它的一半（$size div 2）。如果输入列表可以包含非偶数个元素，则该数字必须四舍五入：（ceiling($size div 2)四舍五入以捕获最后一个元素）

      <xsl:for-each select="catalog/cd[ceiling($size div 2) &gt;= position()]">

在每次迭代中，首先渲染一个元素本身：

        <td><xsl:value-of select="title"/></td>

然后从表格的后半部分渲染一个适当的元素（偏移量是之前定义的数字：ceiling($size div 2)表格的一半大小）

        <td><xsl:value-of select="following::cd[ceiling($size div 2)]/title"/></td>

您可以将元素渲染包装在单独的模板中以避免代码重复。

工作示例

使用 W3C XSL TryIt ( http://www.w3schools.com/xsl/tryxslt.asp?xmlfile=cdcatalog&xsltfile=cdcatalog ) 检查此转换示例：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
  <xsl:param name="size" select="count(catalog/cd)"/>
  <html>
  <body>
  <h2>My CD Collection</h2>
    <table border="1">
      <tr bgcolor="#9acd32">
        <th>Title</th>
        <th>Title</th>
      </tr>
      <xsl:for-each select="catalog/cd[ceiling($size div 2) &gt;= position()]">
      <tr>
        <td><xsl:value-of select="title"/></td>
        <td><xsl:value-of select="following::cd[ceiling($size div 2)]/title"/></td>
      </tr>
      </xsl:for-each>
    </table>
  </body>
  </html>
</xsl:template>
</xsl:stylesheet>

它将 CD 目录（在上面的示例链接中给出）分成两列。

score 0 · Accepted Answer

也许您正在寻找这样的东西：（这仅显示了这个想法，您必须使其适应您的输入。）

 <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
            xmlns="http://www.w3.org/1999/xhtml">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/" >
        <xsl:apply-templates select="//t[count(preceding-sibling::t) &lt; 3]" mode="tables" />

    </xsl:template>
    <xsl:template match="t" >
        {<xsl:value-of select="text()"/>}
    </xsl:template>

    <xsl:template match="t" mode="tables">
        <table border="1">
            <tr>
                <td>
                    <table border="1" >
                        <xsl:apply-templates select="." />
                    </table>
                </td>
                <td>
                    <table border="1">
                        <xsl:apply-templates select="following-sibling::t[count(preceding-sibling::t) = count(current()/preceding-sibling::t) +3]" />
                    </table>
                </td>
            </tr>
        </table>
    </xsl:template>
</xsl:stylesheet>

使用这个简短的测试输入 xml：

<?xml version="1.0" encoding="utf-8"?>
<xml>
    <tables>
        <t>1</t>
        <t>2</t>
        <t>3</t>
        <t>4</t>
        <t>5</t>
        <t>6</t>
    </tables>
</xml>

它将生成以下输出：

<?xml version="1.0"?>
<table xmlns="http://www.w3.org/1999/xhtml" border="1">
  <tr>
    <td>
      <table border="1">
        {1}
    </table>
    </td>
    <td>
      <table border="1">
        {4}
    </table>
    </td>
  </tr>
</table><table xmlns="http://www.w3.org/1999/xhtml" border="1">
  <tr>
    <td>
      <table border="1">
        {2}
    </table>
    </td>
    <td>
      <table border="1">
        {5}
    </table>
    </td>
  </tr>
</table><table xmlns="http://www.w3.org/1999/xhtml" border="1">
  <tr>
    <td>
      <table border="1">
        {3}
    </table>
    </td>
    <td>
      <table border="1">
        {6}
    </table>
    </td>
  </tr>
</table>

xslt - 使用 XSLT 的两列表

2 回答 2

Related

Reference