arrays - Perl：无限循环数组？

Question

我需要一个无限循环进入有限数组......

例子：

@name = ('John', 'Helen', 'Dave');

1=John
2=Helen
3=Dave 
4=John
5=Helen
6=Dave 
7=John
8=Helen
9=Dave 
...etc

可能吗？
谢谢

Answer 1

我不知道为什么有人会想要这样做，但这会做你想做的事：

my $i=0;
my $cnt=1;
my @name = ('John', 'Helen', 'Dave');

    while($i<scalar (@name )){

        print $cnt."".$name[$i];
        $i++;
        $cnt++;
        $i=$i==scalar(@name)?0:$i;


}

Answer 2

听起来好像您需要使用索引号以数组大小为模来索引有限数组：

foreach my $i (1..100) { printf "%d=%s\n", $i, $name[$i % scalar(@name)]; }

my @dow = ( 'Sun', 'Mon', 'Tue', 'Wed', 'Thu', 'Fri', 'Sat' );
print $dow[7 % scalar(@dow)], "\n";
print $dow[125 % scalar(@dow)], "\n";

等等。

Answer 3

为了好玩，这呈现了一个“无限”大的重复值数组（同时只存储每个值的一个副本）。

use InfinitelyLoopingArray qw( );

tie my @dow_lookup, InfinitelyLoopingArray::,
   qw( Sun Mon Tue Wed Thu Fri Sat );

printf "%3d %s\n", $_, $dow_lookup[$_]
   for 0..9, 125;

其中InfinitelyLoopingArray.pm包含：

package InfinitelyLoopingArray;

use strict;
use warnings;

use Carp qw( croak );

sub TIEARRAY {
   my $class = shift;
   return bless([ @_ ], $class);
}

sub FETCHSIZE {
   # Largest supported array index.
   # Currently 2**31-1 or 2**63-1 depending on the build.
   return unpack('J', pack('j', -1)) >> 1;
}

sub FETCH {
   my ($self, $idx) = @_;
   croak "Negative indexes not supported" if $idx < 0;
   return $self->[$idx % @$self];
}

sub new {
   tie my @array, @_;
   return \@array;
}

1;

Answer 4

很多答案 - 还有一个

my(@names) = ('John', 'Helen', 'Dave');
my $cnt;
while(1) {
    print ++$cnt, "=$_\n" for (@names);
}

希望，这已经足够无限了...... :)/至少在 $cnt 溢出时/