xml - 通过匹配 id 将两个不同格式的 XML 文件与 XSLT 合并

Question

我的 XML 之一是这样的：

<people>
    <person code="111" name="Bob" />
    <person code="222" name="Sue" />
</people>

另一个是这样的：

<people>
    <person>
        <id>111</id>
        <age>80</age>
    </person>
    <person>
        <id>222</id>
        <age>73</age>
    </person>
</people>

第一个文件中的“代码”与第二个文件中的“id”相同。

我想合并这两个来得到这个：

<people>
    <person>
        <id>111</id>
        <name>Bob</name>
        <age>80</age>
    </person>
    <person>
        <id>222</id>
        <name>Sue</name>
        <age>73</age>
    </person>
</people>

如何使用 XSLT 做到这一点？

Answer 1

如果第一人称文件包含您关心的所有人员 ID，您可以执行以下操作。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
            >
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="person">
        <person>
            <id>
                <xsl:value-of select="@code"/>
            </id>
            <name>
                <xsl:value-of select="@name"/>
            </name>
            <xsl:for-each select="document('ip2.xml')//person[id=current()/@code]">
                <xsl:apply-templates  />
            </xsl:for-each>
        </person>
    </xsl:template>
    <xsl:template match="id" />
    <xsl:template match="node() | @*">
        <xsl:copy>
        <xsl:apply-templates    />
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

这将生成此输出：

<?xml version="1.0"?>
<people>
    <person>
        <id>111</id>
        <name>Bob</name>
        <age>80</age>
    </person>
    <person>
        <id>222</id>
        <name>Sue</name>
        <age>73</age>
    </person>
</people>