3

Haskell 的简洁和优雅让我印象深刻。但是我在 .Net 公司工作，所以当我可以摆脱它时我会使用 F#——我可能是全国数百个使用它的唯一一个。

ADO.NET 或 F# 是否提供了与 HDBC 一样简洁和优雅的东西executeMany？我正在通过Real World Haskell。在第 21 章中，它提供了这个例子：

ghci> conn <- connectSqlite3 "test1.db"
ghci> stmt <- prepare conn "INSERT INTO test VALUES (?, ?)"
ghci> executeMany stmt [[toSql 5, toSql "five's nice"], [toSql 6, SqlNull]]
ghci> commit conn
ghci> disconnect conn

我想在我的 F# 中获得这种优雅和简洁。我已经看到很多关于使用参数化查询来避免 SQL 注入攻击的炒作。在这种情况下，我不使用它们有以下三个原因：

  1. 我发现 .Net 中的参数化查询丑陋而繁琐。
  2. 我的数据来自公司办公室，所以它（大部分）是干净的。
  3. 我的表有 34 列。我鄙视用 34 列参数化查询的想法。

这是我的 F# 代码：

module Data

open System
open System.Data
open System.Data.OleDb
open System.Text.RegularExpressions

type Period = Prior | Current

let Import period records db =
    use conn = new OleDbConnection(@"Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" + db + ";Persist Security Info=False;")

    let execNonQuery s =
        let comm = new OleDbCommand(s, conn) in
        comm.ExecuteNonQuery() |> ignore

    let enquote = sprintf "\"%s\""
    let escapeQuotes s = Regex.Replace(s, "\"", "\"\"")
    let join (ss:string[]) = String.Join(",", ss)

    let table = match period with
                | Prior   -> "tblPrior"
                | Current -> "tblCurrent"
    let statements =
        [| for r in records do
               let vs = r |> Array.map (escapeQuotes >> enquote) |> join
               let vs' = vs + sprintf ",\"14\",#%s#" (DateTime.Now.ToString "yyyy-MM-dd") in
               yield sprintf "INSERT INTO %s ( [Field01], [Field02], [Field03] [Field04], [Field05], [Field06], [Field07], [Field08], [Field09], [Field10], [Field11], [Field12], [Field13], [Field14], [Field15], [Field16], [Field17], [Field18], [Field19], [Field20], [Field21], [Field22], [Field23], [Field24], [Field25], [Field26], [Field27], [Field28], [Field29], [Field30], [Field31], [Field32], [Field33], [Field34] ) VALUES (%s)" table vs' |] in

    do conn.Open()
    execNonQuery (sprintf "DELETE FROM %s" table)
    statements |> Array.iter execNonQuery

出于安全原因，我已重命名表的字段。

因为表格上的所有字段都是文本，所以我可以轻松地将它们 Array.map 以转义和引用值。

每天有 9,000 到 10,000 条记录要导入到这两个表中的每一个，我希望尽可能高效地执行此操作。因此我对executeManyHaskell 感兴趣。不过，我也喜欢参数化查询背后的想法，也喜欢 Hasekll 实现它们的方式。在 F# 中是否存在与简洁和优雅相当的东西？

4

1 回答 1

7

我同意@JonnyBoats 的评论，即通常使用像SqlDataConnection (LINQ-to-SQL) 或SqlEntityConnection (Entity Framework) 这样的 F# SQL 类型提供程序将比任何涉及手动构建插入语句字符串的解决方案优雅得多。

但是，您的问题有一个重要的限定条件：“每天要导入两个表中的每一个的记录在 9,000 到 10,000 条之间，我希望尽可能高效地执行此操作。” 在这种情况下，您将希望使用SqlBulkCopy进行高效的批量插入（它利用本机数据库驱动程序功能来实现比 HDBC 更快的插入速度executeMany）。

这是一个可以帮助您开始使用SqlBulkCopyF# 的小示例：https ://stackoverflow.com/a/8942056/236255 。请注意，您将使用DataTable来暂存数据，虽然这些数据在 F# 中使用起来有些陈旧且有些尴尬，但在我看来仍然优于构建插入语句字符串。

更新以回应评论

这是针对您的场景进行改进的通用方法SqlBulkCopy（我们将列规范与行数据分开传递，并且两者都是动态的）：

//you must reference System.Data and System.Xml
open System
open System.Data
open System.Data.SqlClient

let bulkLoad (conn:SqlConnection) tableName (columns:list<string * Type>) (rows: list<list<obj>>) =
    use sbc = new SqlBulkCopy(conn, SqlBulkCopyOptions.TableLock, null, BatchSize=500, BulkCopyTimeout=1200, DestinationTableName=tableName)
    sbc.WriteToServer(
        let dt = new DataTable()
        columns
        |> List.iter (dt.Columns.Add>>ignore)

        for row in rows do
            let dr = dt.NewRow()
            row |> Seq.iteri(fun i value -> dr.[i] <- value)
            dt.Rows.Add(dr)
        dt)

//example usage:

//note: since you know all your columns are of type string, you could define columns like
//let columns = ["Field1", "Field2", "Field3"] |> List.map (fun name -> name, typeof<String>)
let columns = [
    "Field1", typeof<String>
    "Field2", typeof<String>
    "Field3", typeof<String>
]

let rows = [
    ["a"; "b"; "c"]
    ["d"; "e"; "f"]
    ["g"; "h"; "i"]
    ["j"; "k"; "l"]
    ["m"; "n"; "o"]
]

//a little funkiness to transform our list<list<string>> to list<list<obj>>, 
//probably not needed in practice because you won't be constructing your lists literally
let rows = rows |> List.map (fun row -> row |> List.map (fun value -> value :> obj))

bulkLoad conn "tblPrior" columns rows

使用涉及反射的方法，您可以变得更花哨/更简洁。例如创建一个类型

type RowData = { Field1:string; Field2:string; Field3:string }

并使用bulkLoad带有list<'a>参数的签名制作 a ，以便它反映属性名称和类型typeof<'a>来构建DataTable Columns，并且类似地使用反射来迭代行实例的所有属性以创建新行并将其添加到DataTable. 事实上，这个问题展示了如何制作一个通用ToDataTable方法来完成它（在 C# 中）。

于 2013-05-01T16:32:55.520 回答