toggle - 如何打开和关闭一组键绑定？

Question

我正在尝试设置一组键绑定，只需按一下按钮即可打开和关闭它们，但无法在任何地方找到任何示例。

我希望 ^NumpadSub 在我按下 ^NumpadSub 时切换这些不同的键绑定以打开和关闭它们。

q::w
z::s
w::up
s::down

谁能帮助我如何设置代码来做到这一点？

Answer 1

如果只有这些，您可以再添加一个热键：

^NumpadSub::Suspend

这将暂停所有热键（用于切换暂停开/关的热键除外）

否则，您将不得不使用实际的热键功能（http://www.autohotkey.com/docs/commands/Hotkey.htm），它允许您打开/关闭热键，但热键功能指的是标签：（转到地址）。

如果您只想让这些键在您使用一个特定的应用程序（游戏）时以某种方式起作用，您可以使用#IfWinActive 命令。

例如

SetTitleMatchMode, 2
#IfWinActive, Notepad ; Start of Notepad specific keys.
a::Send, Haha
b::SoundBeep, 500, 500
#IfWinActive ; End of Notepad specific keys.

在这种情况下，看看这是否适合你！我在 w 和 s 前面添加了 $ 符号，因为点击 q 和 z 会触发 w 和 s 的执行

Hotkey, q , MyQ, On
Hotkey, z , MyZ, On
Hotkey, $w , MyW, On
Hotkey, $s , MyS, On
Return

^NumpadSub::
KeyToggle:=!KeyToggle
Hotkey, q , % (KeyToggle ? "Off": "On")
Hotkey, z , % (KeyToggle ? "Off": "On")
Hotkey, $w , % (KeyToggle ? "Off": "On")
Hotkey, $s , % (KeyToggle ? "Off": "On")
Return

MyQ:
SendInput, w
Return

MyZ:
SendInput, s
Return

MyW:
SendInput, {Up}
Return

MyS:
SendInput, {Down}
Return