1

我的一些文件有问题，可以使用帮助解决它。我正在从 html 转换为 xml。有时我自己有一个<b>或<u>或<i>标签，我使用

<xsl:template match="i">
<emphasis italic="yes">
<xsl:apply-templates select="*|@*|text()"/>
</emphasis>
</xsl:template>

或 b 为粗体，u 为下划线。

有时我有一个嵌套<u>在一个<b>

对于这些我使用

<xsl:template match="b/u">
<xsl:apply-templates select="*|@*|text()"/>
</xsl:template>

这是为了摆脱u

<xsl:template match="b[u]">
<emphasis bold="yes" underline="yes">
<xsl:apply-templates select="*|@*|text()"/>
</emphasis>
</xsl:template>

这是转换b后跟一个u.

现在我的问题是当它u嵌套在一个i嵌套在一个b. 这个代码是什么？

4

2 回答 2

0

这是一个简单而简短的解决方案：只有两个模板，没有明确的条件说明：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <my:names>
   <n short="b">bold</n>
   <n short="i">italic</n>
   <n short="u">underline</n>
 </my:names>

 <xsl:variable name="vNames" select="document('')/*/my:names/*"/>

 <xsl:template match=
  "node()[not(contains('+b+i+u+', concat('+',name(),'+')))]
         /*[contains('+b+i+u+', concat('+',name(),'+'))]
  ">
   <emphasis>
      <xsl:apply-templates select="." mode="emph"/>
   </emphasis>
  </xsl:template>

 <xsl:template mode="emph"
   match="*[contains('+b+i+u+', concat('+',name(),'+'))]">
   <xsl:attribute name="{$vNames[@short=name(current())]}">yes</xsl:attribute>
   <xsl:apply-templates select="node()" mode="emph"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<test>
   <b>bold</b>
   <i>Italic</i>
   <b><i>bold Italic</i></b>
   <u><b><i>bold Italic underline</i></b></u>
</test>

产生了想要的正确结果：

<emphasis bold="yes">bold</emphasis>
<emphasis italic="yes">Italic</emphasis>
<emphasis bold="yes" italic="yes">bold Italic</emphasis>
<emphasis underline="yes" bold="yes" italic="yes">bold Italic underline</emphasis>
于 2013-05-01T03:27:10.860 回答
0

在回答你的直接问题时，要匹配一个u嵌套在一个i嵌套在一个中，b你会这样做

<xsl:template match="b/i/u">

您还需要模板来处理父级b和i

<xsl:template match="b[i/u]">

<xsl:template match=b/i[u]">

但是大概你想处理以任何顺序嵌套的元素？并且为每个可能的排列编码模板会变得非常混乱，而且您还必须担心两个模板匹配相同的元素。

相反，试试这个稍微灵活一点的 XSLT，虽然不是特别优雅

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="i[parent::b|parent::u]" name="italic">
      <xsl:attribute name="italic">yes</xsl:attribute>
      <xsl:apply-templates select="*|@*|text()"/>
   </xsl:template>

   <xsl:template match="b[parent::i|parent::u]" name="bold">
      <xsl:attribute name="bold">yes</xsl:attribute>
      <xsl:apply-templates select="*|@*|text()"/>
   </xsl:template>

   <xsl:template match="u[parent::b|parent::i]" name="underline">
      <xsl:attribute name="underline">yes</xsl:attribute>
      <xsl:apply-templates select="*|@*|text()"/>
   </xsl:template>   

   <xsl:template match="*[self::b|self::i|self::u][not(parent::b)][not(parent::i)][not(parent::u)]">
      <emphasis>
         <xsl:choose>
            <xsl:when test="self::b">
            <xsl:call-template name="bold"/>
            </xsl:when>
            <xsl:when test="self::i">
            <xsl:call-template name="italic"/>
            </xsl:when>
            <xsl:when test="self::u">
            <xsl:call-template name="underline"/>
            </xsl:when>
         </xsl:choose>
      </emphasis>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

这个想法是你有模板匹配i，b或者u元素有其他元素作为父元素。在这种情况下，您只需输出相关属性。

您还拥有与输出强调i元素的最顶部b或u元素（即没有其他此类元素作为父元素的元素）匹配的主模板。注意命名模板的使用更简单，以避免一些代码重复。

当您将其应用于以下 XML

<test>
   <b>bold</b>
   <i>Italic</i>
   <b><i>bold Italic</i></b>
   <u><b><i>bold Italic underline</i></b></u>
</test>

以下是输出

<test>
   <emphasis bold="yes">bold</emphasis>
   <emphasis italic="yes">Italic</emphasis>
   <emphasis bold="yes" italic="yes">bold Italic</emphasis>
   <emphasis underline="yes" bold="yes" italic="yes">bold Italic underline</emphasis>
</test>
于 2013-04-30T21:43:58.650 回答