8

我正在使用出色的 Inno Setup 安装程序，我注意到一些应用程序（通常来自 Microsoft）安装时，它们的启动图标在开始菜单（在 Windows 7 中）中已经非常明显（“固定？”）。我是否完全依赖最近使用的算法让我的图标在开始菜单中变“大”，或者有没有办法从安装程序中推广我的应用程序？

4

3 回答 3

8

可以固定程序，但不是正式的。基于发布的代码this thread（使用与@Mark Redman 链接的文章中描述的相同方式），我编写了以下内容：

[Code]
#ifdef UNICODE
  #define AW "W"
#else
  #define AW "A"
#endif

const
  // these constants are not defined in Windows
  SHELL32_STRING_ID_PIN_TO_TASKBAR = 5386;
  SHELL32_STRING_ID_PIN_TO_STARTMENU = 5381;
  SHELL32_STRING_ID_UNPIN_FROM_TASKBAR = 5387;
  SHELL32_STRING_ID_UNPIN_FROM_STARTMENU = 5382;

type
  HINSTANCE = THandle;
  HMODULE = HINSTANCE;

  TPinDest = (
    pdTaskbar,
    pdStartMenu
  );

function LoadLibrary(lpFileName: string): HMODULE;
  external 'LoadLibrary{#AW}@kernel32.dll stdcall';
function FreeLibrary(hModule: HMODULE): BOOL;
  external 'FreeLibrary@kernel32.dll stdcall';
function LoadString(hInstance: HINSTANCE; uID: UINT;
  lpBuffer: string; nBufferMax: Integer): Integer;
  external 'LoadString{#AW}@user32.dll stdcall';

function TryGetVerbName(ID: UINT; out VerbName: string): Boolean;
var
  Buffer: string;
  BufLen: Integer;
  Handle: HMODULE;
begin
  Result := False;

  Handle := LoadLibrary(ExpandConstant('{sys}\Shell32.dll'));
  if Handle <> 0 then
  try
    SetLength(Buffer, 255);
    BufLen := LoadString(Handle, ID, Buffer, Length(Buffer));

    if BufLen <> 0 then
    begin
      Result := True;
      VerbName := Copy(Buffer, 1, BufLen);
    end;
  finally
    FreeLibrary(Handle);
  end;
end;

function ExecVerb(const FileName, VerbName: string): Boolean;
var
  I: Integer;
  Shell: Variant;
  Folder: Variant;
  FolderItem: Variant;
begin
  Result := False;

  Shell := CreateOleObject('Shell.Application');
  Folder := Shell.NameSpace(ExtractFilePath(FileName));
  FolderItem := Folder.ParseName(ExtractFileName(FileName));

  for I := 1 to FolderItem.Verbs.Count do
  begin
    if FolderItem.Verbs.Item(I).Name = VerbName then
    begin
      FolderItem.Verbs.Item(I).DoIt;
      Result := True;
      Exit;
    end;
  end;  
end;

function PinAppTo(const FileName: string; PinDest: TPinDest): Boolean;
var
  ResStrID: UINT;
  VerbName: string;
begin
  case PinDest of
    pdTaskbar: ResStrID := SHELL32_STRING_ID_PIN_TO_TASKBAR;
    pdStartMenu: ResStrID := SHELL32_STRING_ID_PIN_TO_STARTMENU;
  end;
  Result := TryGetVerbName(ResStrID, VerbName) and ExecVerb(FileName, VerbName);
end;

function UnpinAppFrom(const FileName: string; PinDest: TPinDest): Boolean;
var
  ResStrID: UINT;
  VerbName: string;
begin
  case PinDest of
    pdTaskbar: ResStrID := SHELL32_STRING_ID_UNPIN_FROM_TASKBAR;
    pdStartMenu: ResStrID := SHELL32_STRING_ID_UNPIN_FROM_STARTMENU;
  end;
  Result := TryGetVerbName(ResStrID, VerbName) and ExecVerb(FileName, VerbName);
end;

上面的代码首先从库的字符串表中读取用于固定或取消固定应用程序的菜单项的标题Shell32.dll。然后连接到 Windows Shell，并连接到目标应用程序。path 创建Folder对象，然后获取对象并在此对象上迭代所有可用的动词并检查它们的名称是否与从库字符串表中FolderItem读取的名称匹配。Shell32.dll如果是这样，它通过调用该DoIt方法来调用动词项操作并退出迭代。

这是上述代码的可能用法，用于固定：

if PinAppTo(ExpandConstant('{sys}\calc.exe'), pdTaskbar) then
  MsgBox('Calc has been pinned to the taskbar.', mbInformation, MB_OK);
if PinAppTo(ExpandConstant('{sys}\calc.exe'), pdStartMenu) then
  MsgBox('Calc has been pinned to the start menu.', mbInformation, MB_OK);

对于取消固定：

if UnpinAppFrom(ExpandConstant('{sys}\calc.exe'), pdTaskbar) then
  MsgBox('Calc is not pinned to the taskbar anymore.', mbInformation, MB_OK);
if UnpinAppFrom(ExpandConstant('{sys}\calc.exe'), pdStartMenu) then
  MsgBox('Calc is not pinned to the start menu anymore.', mbInformation, MB_OK);

请注意，即使此代码在 Windows 7 上工作（并且任务栏固定也可以在我测试过的 Windows 8.1 上），它确实是一种 hacky 方式，因为没有官方方法可以以编程方式将程序固定到任务栏，也没有开始菜单。这就是用户应该根据自己的选择去做的事情。

于 2014-07-31T18:08:24.880 回答
6

没有以编程方式将内容固定到任务栏/开始菜单是有原因的。根据我的经验，我已经看到开始菜单突出显示了新创建的快捷方式，而这正是为了处理这种情况而设计的。当您在开始菜单上看到新安装的程序时，可能是因为该算法，而不是因为安装程序将它放在那里。

也就是说，如果新的快捷方式没有突出显示，可能是因为安装程序提取了预先存在的快捷方式并在其上保留了旧的时间戳，而不是使用 API 函数在开始菜单中创建快捷方式。

于 2009-10-27T08:27:39.403 回答