4

我是 Excel VBA 的初学者，非常感谢您的帮助。

请建议我如何创建一个打开和数据库连接的通用函数，以及另一个关闭它的函数，以避免重复编码？

这是我的代码。我被困在如何继续前进...

Const connection_string As String = "Provider=SQLOLEDB.1;Password=XXX;Persist Security              `Info=True;User ID=sa;Initial Catalog=TESTDB;Data Source=XXXX;"

Sub DuplicateDBConnection()

'Declare variables
Set cn1 = New ADODB.Connection
Set cmd1 = New ADODB.Command
Set rs1 = New ADODB.Recordset

'Open Connection
cn1.ConnectionString = connection_string
cn1.Open

'Set and Excecute SQL Command
Set cmd1.ActiveConnection = cn1
cmd1.CommandText = "Select stock_code, name, sector_id from stock_master"
cmd1.CommandType = adCmdText
cmd1.Execute

'Open Recordset
Set rs1.ActiveConnection = cn1
rs1.Open cmd1

'Copy Data to Excel
ActiveSheet.Range("A1").CopyFromRecordset (rs1)

'Close Connection
rs1.Close
cn1.Close

'Throw Object
Set rs1 = Nothing
Set cn1 = Nothing

End Sub

我的愿望是编写通用函数，这样我就不需要继续编写代码来连接和关闭连接。

Sub ConnectDB()
    'Codes to connect DB
End Sub

Sub CloseConnnection()
    'Codes to close connection
End Sub

Sub ExecuteCode()
    ConnectDB
    'Execute SQL command to manipulate data on excel and SQL database 
    CloseConnection
End Sub

根据 Kittoe 的建议进行编辑，现在可以正常工作。谢谢！

  1. 类：A。创建了一个名为 AdoDbHelper 的类 Private Instancing b。在 AdoDbHelper 中，将“选项比较数据库”更改为“选项比较文本”

  2. 模块：创建一个这样的函数。

下面的代码：

Const connection_string As String = "Provider=SQLOLEDB.1;Password=XXX;Persist Security              `Info=True;User ID=sa;Initial Catalog=TESTDB;Data Source=XXXX;"

Sub Test()

Dim sourceDb As New AdoDbHelper
Dim sourceRs As New ADODB.Recordset

sourceDb.Connect (connection_string)

Set sourceRs = sourceDb.OpenRecordset("Select stock_code, name, sector_id from     stock_master")

With sourceRs
    'Do stuff!

     ActiveSheet.Range("A1").CopyFromRecordset sourceRs

    .Close
End With

sourceDb.Disconnect

Set sourceRs = Nothing
Set sourceDb = Nothing

End Sub
4

2 回答 2

6

这种类型的东西最好在课堂上完成。在“IDE”中右键单击您的 VBA 项目，然后转到 Insert -> Class Module。将您的类命名为有意义的名称，例如 clsAdoHelper（如果您喜欢匈牙利表示法）、AdoDbHelper 或其他名称。以下是您在此类中放入的代码示例：

Option Compare Database
Option Explicit

Private WithEvents conn As ADODB.Connection
Private WithEvents rs As ADODB.Recordset

Public Sub Connect(ConnectionString As String)
    If Not conn Is Nothing Then
        Debug.Print "A connection is already open."
        Exit Sub
    End If

    If ConnectionString = CurrentProject.Connection.ConnectionString Then
        Set conn = CurrentProject.Connection
    Else
        Set conn = New ADODB.Connection
        conn.Open ConnectionString
    End If
End Sub

Public Sub Disconnect()
    If Not conn Is Nothing Then
        If conn.State <> 0 Then
            conn.Close
        End If

        Set conn = Nothing
    End If
End Sub

Public Sub Execute(SQL As String)
    If conn Is Nothing Then
        Debug.Print "No connection open."
        Exit Sub
    End If

    conn.Execute (SQL)
End Sub

Public Function OpenRecordset(SQL As String, Optional CursorLocation As ADODB.CursorLocationEnum = adUseClient, Optional CursorType As ADODB.CursorTypeEnum = adOpenForwardOnly, Optional LockType As ADODB.LockTypeEnum = adLockReadOnly) As ADODB.Recordset
    If conn Is Nothing Then
        Debug.Print "No connection open."
        Exit Function
    End If

    If Not rs Is Nothing Then
        Debug.Print "A recordset is already open."
        Exit Function
    End If

    Set rs = New ADODB.Recordset

    With rs
        .CursorLocation = CursorLocation
        .CursorType = CursorType
        .LockType = LockType
        .Open SQL, conn
    End With

    Set OpenRecordset = rs
End Function

Public Sub BeginTransaction()
    conn.BeginTrans
End Sub

Public Sub CommitTransaction()
    conn.CommitTrans
End Sub

Public Sub RollbackTransaction()
    conn.RollbackTrans
End Sub

Private Sub conn_BeginTransComplete(ByVal TransactionLevel As Long, ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pConnection As ADODB.Connection)
    Debug.Print "Transaction started."
End Sub

Private Sub conn_CommitTransComplete(ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pConnection As ADODB.Connection)
    Debug.Print "Transaction committed."
End Sub

Private Sub conn_ConnectComplete(ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pConnection As ADODB.Connection)

End Sub

Private Sub conn_Disconnect(adStatus As ADODB.EventStatusEnum, ByVal pConnection As ADODB.Connection)

End Sub

Private Sub conn_ExecuteComplete(ByVal RecordsAffected As Long, ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pCommand As ADODB.Command, ByVal pRecordset As ADODB.Recordset, ByVal pConnection As ADODB.Connection)
    Debug.Print "SQL execution complete."
End Sub

Private Sub conn_RollbackTransComplete(ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pConnection As ADODB.Connection)
    Debug.Print "Transaction rolled back."
End Sub

使用您的新课程：

Dim sourceDb As New AdoDbHelper
Dim sourceRs as New ADODB.Recordset

sourceDb.Connect (<insert connection string here>)

Set sourceRs = sourceDb.OpenRecordSet(<insert SQL string here>)

With sourceRs
    'Do stuff!

    .Close
End With

sourceDb.Disconnect

Set sourceRs = Nothing
Set sourceDb = Nothing

这不是我写过的最好的代码，但它应该给你一个不错的开始。如果您无法理解该类的工作原理，我鼓励您对 OOP 和 VBA 中的类进行一些研究。您会注意到您仍然有一些必要的 biolerplate 代码，但大部分正常工作已经在类方法中为您处理好了。如果您想将数据操作逻辑放入它自己的函数中，您可以将您使用类创建的 ADODB.Recordset 对象传递给它（这将替换WITH块）。

我不建议使用这样的逻辑来污染类，因为您希望该类处理所有可能的 ADODB 连接的通用连接/断开/异常处理。这样你就可以在其他项目中重用它=D。

于 2013-04-29T16:54:45.037 回答
1

使用 Microsoft ActiveX 数据对象库 xx：

在您的 VBA 窗口中，转到工具 > 参考 > Microsoft ActiveX 数据对象库 xx

我通常使用 2.7 来向下兼容。现在，您可以创建 ADODB 对象以打开连接、执行查询（选择/更新/删除/...）并将查询结果（称为记录集）用于您的 excel 的其余部分、表格、特定单元格中。

为确保始终使用相同的连接，请创建一个公共连接对象并在所有子例程中引用它。在每个子例程中，首先检查它是否已经由（conn作为我的ADODB.Connection对象）设置：

If conn = Nothing Then Call Setup_Connection

子程序 Setup_Connection 类似于：

Private Sub Setup_Connection
    Dim strConnection as String

    If conn = Nothing Then
        'Choose your own database connection details
        strConnection = "Provider=SQLOLEDB.1;Integrated Security=SSPI;" & _
                "Persist Security Info=False;" & _
                "Initial Catalog=DatabaseName;" & _
                "Data Source=DATABASESERVER"
        Set conn = New ADODB.Connection
        With conn
            .Open strConnection
            .CommandTimeout = 30
        End With
    End If
End Sub
于 2013-04-29T15:18:32.853 回答