0

下面是我的 xml 和 xslt 字符串..

 xml='<SampleXML>
        <header>
            <Id>123</Id>
        </header>
        <properties>
            <property name="a1_name1" value="apple"/>
            <property name="a1_name2" value="SALE"/>
            <property name="a2_name3" value="20130425"/>
        </properties>

    </SampleXML>


';

xslt ="<xsl:stylesheet xmlns:xsl=\"http://www.w3.org/1999/XSL/Transform\" version=\"1.0\">
    <xsl:template match=\"SampleXML/header\"/>  
    <xsl:template match=\"SampleXML/properties\">
        <xsl:apply-templates select=\"property[position() = 1]\">
            <xsl:with-param name=\"mode\">name</xsl:with-param>
        </xsl:apply-templates>;<xsl:apply-templates select=\"property[position() = 1]\">
            <xsl:with-param name=\"mode\">value</xsl:with-param>
        </xsl:apply-templates>~</xsl:template>

  <xsl:template match=\"property\">
    <xsl:param name=\"mode\" />
    <xsl:if test=\"$mode='name'\">
        <xsl:variable name=\"sub\"><xsl:apply-templates select=\"following-sibling::*[1]\"><xsl:with-param name=\"mode\" select=\"$mode\"/></xsl:apply-templates></xsl:variable>
        <xsl:value-of select=\"@name\"/>|<xsl:value-of select=\"$sub\"/>
    </xsl:if>
    <xsl:if test=\"$mode='value'\">
        <xsl:variable name=\"sub\"><xsl:apply-templates select=\"following-sibling::*[1]\"><xsl:with-param name=\"mode\" select=\"$mode\"/></xsl:apply-templates></xsl:variable>
        <xsl:value-of select=\"@value\"/>|<xsl:value-of select=\"$sub\"/>
    </xsl:if>
  </xsl:template>    
</xsl:stylesheet>";

这给了我一个输出

<?xml version="1.0"?>
a1_name1|a1_name2|a2_name3|;apple|SALE|20130425|~

如何修改 xslt 以仅在输出中查看前缀为“a1”的内容。类似下面的内容..尝试使用模板匹配但没有运气。

<?xml version="1.0"?>
a1_name1|a1_name2;apple|SALE~
4

2 回答 2

0

尝试这样的事情：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template match="SampleXML/header"/>
    <xsl:template match="SampleXML/properties">
        <xsl:for-each select="property[starts-with(@name,'a1')]">
            <xsl:value-of select="@name"/>
            <xsl:if test ="position() != last()">
                <xsl:text>|</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>;</xsl:text>
        <xsl:for-each select="property[starts-with(@name,'a1')]">
            <xsl:value-of select="@value"/>
            <xsl:if test ="position() != last()">
                <xsl:text>|</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>~</xsl:text>
</xsl:template>
</xsl:stylesheet>

这将产生：

   a1_name1|a1_name2;apple|SALE~
于 2013-04-26T19:35:11.170 回答
0

在回答您的问题时，如果您想排除名称属性以“a1”开头的属性元素，只需添加以下模板即可忽略

<xsl:template match="property[not(starts-with(@name, 'a1_'))]" />

注意这个模板是如何立即关闭的，所以是空的。换句话说，它什么也不做。当它匹配 name 属性不以 'a1_' 开头的属性元素时，不会输出任何内容。

XSLT 处理器将首先匹配最具体的模板，因此该处理器将优先忽略这些元素。

但是，值得注意的是，您可以稍微简化当前的 XSLT。您当前正在传递模式属性，以确定要输出的属性。另一种方法如下：

<xsl:template match="property">
    <xsl:param name="mode"/>
    <xsl:value-of select="@*[name() = $mode]"/>
    <xsl:text>|</xsl:text>
</xsl:template>

请注意，不需要一次调用xsl:apply-templates一个元素，只需在单个语句中选择它们。

<xsl:apply-templates select="property">
   <xsl:with-param name="mode" select="'name'"/>
</xsl:apply-templates>

它们将按顺序选择，因此不会成为问题。试试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:template match="SampleXML/header"/>

   <xsl:template match="SampleXML/properties">
      <xsl:apply-templates select="property">
         <xsl:with-param name="mode" select="'name'"/>
      </xsl:apply-templates>
      <xsl:text>;</xsl:text>
      <xsl:apply-templates select="property">
         <xsl:with-param name="mode" select="'value'"/>
      </xsl:apply-templates>
      <xsl:text>~</xsl:text>
   </xsl:template>

   <xsl:template match="property[not(starts-with(@name, 'a1_'))]"/>

   <xsl:template match="property">
      <xsl:param name="mode"/>
      <xsl:value-of select="@*[name() = $mode]"/>
      <xsl:text>|</xsl:text>
   </xsl:template>
</xsl:stylesheet>

当应用于您的 XML 时，将输出以下内容

a1_name1|a1_name2|;apple|SALE|~
于 2013-04-26T18:59:44.837 回答