5

我正在尝试获取一组随机点 (x,y) 以将图形节点绘制到屏幕上。我需要为传入的每个节点名称随机生成一个点。

我在 SO 页面上找到了此代码，并对其进行了一些修改以适合我，但它并没有真正满足我的需要。

我需要一个随机列表（尽可能随机）（Int，Int）。

无论如何，这是我到目前为止所拥有的，当然，它每次都给出相同的值，所以它不是特别随机 :)

rndPoints :: [String] -> [Point]
rndPoints [] = []
rndPoints xs = zip x y where
          size = length xs
          x = take size (tail (map fst $ scanl (\(r, gen) _ -> randomR (25::Int,1000::Int) gen) (random (mkStdGen 1)) $ repeat ()))
          y = take size (tail (map fst $ scanl (\(r, gen) _ -> randomR (25::Int,775::Int) gen) (random (mkStdGen 1)) $ repeat ()))

任何帮助将非常感激。

4

2 回答 2

7

首先，让我们稍微清理一下您的代码。有一个复数版本，randomR它提供了一个无限的随机值列表：randomRs. 这简化了一些事情：

rndPoints1 :: [String] -> [Point]
rndPoints1 [] = []
rndPoints1 xs = zip x y
  where
    size = length xs
    x = take size $ randomRs (25, 1000) (mkStdGen 1)
    y = take size $ randomRs (25,  775) (mkStdGen 1)

我们可以进一步简化这一点，通过使用zip' 在较短的列表耗尽后停止的属性：

rndPoints2 :: [a] -> [Point]
rndPoints2 xs = map snd $ zip xs $ zip x y
  where
    x = randomRs (25, 1000) (mkStdGen 1)
    y = randomRs (25,  775) (mkStdGen 1)

请注意，我还将传入列表的类型概括为[a]. 由于从未使用过这些值，因此它们不必是Strings!

现在，它每次都给出相同的值，因为它每次都使用相同的种子 ( )mkStdGen创建一个伪随机生成器。1如果您希望它每次都不同，那么您需要创建一个生成器，IO其中可以基于计算机的随机状态。与其将整个计算放入 中，不如IO传入 a 更简洁StdGen：

rndPoints3 :: StdGen -> [Point]
rndPoints3 sg = zip x y
  where
    (sg1, sg2) = split sg
    x = randomRs (25, 1000) sg1
    y = randomRs (25,  775) sg2

pointsForLabels :: [a] -> StdGen -> [(a, Point)]
pointsForLabels xs sg = zip xs $ rndPoints3 sg

example3 :: [a] -> IO [(a, Point)]
example3 xs = newStdGen >>= return . pointsForLabels xs

在这里，newStdGen每次都会创建一个新的伪随机生成器，但它在IO. 最终将其传递给一个纯（非IO）函数，该函数rndPoints3采用生成器，并返回一个无限的随机Points 列表。在该函数中，split用于从中创建两个生成器，每个生成器用于导出坐标的随机列表。

pointsForLables现在分离出为每个标签匹配一个新的随机点的逻辑。我还更改了它以返回更可能有用的标签对和Points。

最后，example3生活在 中IO，并创建生成器并将其全部传递到其他纯代码中。

于 2013-04-25T06:45:05.673 回答
0

我最终为此使用了 MonadRandom。我认为代码更清晰，更容易理解。您可以修改以下代码来解决原始问题。

import Control.Applicative
import Control.Monad.Random

type Point = (Float, Float)
type Poly = [Point]

randomScalar :: (RandomGen g) => Rand g Float
randomScalar = getRandomR (-500, 500)

randomPoint :: (RandomGen g) => Rand g Point
randomPoint = (,) <$> randomScalar <*> randomScalar

randomPoly :: (RandomGen g) => Int -> Rand g Poly
randomPoly n = sequence (replicate n randomPoint)
于 2015-03-26T04:04:35.687 回答