7

我知道我在这里遗漏了一些东西。在下面的 XSLT 转换中，实际结果与期望的结果不匹配。

在内部for-each，我想将match="track"模板应用于每个选定的track元素。如果我正确理解了 XSLT，那么在当前设置下，只有每个选定track元素的子节点与模板匹配，而不是track元素本身。

如何使track元素根据需要通过模板？我需要重新考虑我的整个方法吗？

注意：转换是使用 PHP 执行的。为简洁起见，省略了 XML 声明。

XML 文档：

<album>
    <title>Grave Dancers Union</title>
    <track id="shove">Somebody To Shove</track>
    <track id="gold">Black Gold</track>
    <track id="train">Runaway Train</track>
    <producer>Michael Beinhorn</producer>
</album>

XSL 样式表：

<xsl:stylesheet version="1.1" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/album">
        <ol>
            <xsl:for-each select="track">
                <li><xsl:apply-templates/></li>
            </xsl:for-each>
        </ol>
    </xsl:template>

    <xsl:template match="track">
        <a href="{@id}"><xsl:apply-templates/></a>
    </xsl:template>
</xsl:stylesheet>

结果：

<ol>
    <li>Somebody To Shove</li>
    <li>Black Gold</li>
    <li>Runaway Train</li>
</ol>

期望的结果：

<ol>
    <li><a href="shove">Somebody To Shove</a></li>
    <li><a href="gold">Black Gold</a></li>
    <li><a href="train">Runaway Train</a></li>
</ol>
4

4 回答 4

14

我同意“ndim”的观点，即您可能应该重组您的 XSLT 以取消 xsl:for-each 循环。

或者，您可以修改 xsl:apply-templates 以选择 xsl:for-each 中的当前轨道节点

<xsl:for-each select="track">
   <li>
      <xsl:apply-templates select="." />
   </li>
</xsl:for-each>

如果需要，保留 xsl:for-each 至少可以让您以其他顺序对曲目进行排序。

于 2009-10-25T10:43:00.230 回答
4

我会对其进行一些重组（如果您不需要排序for-each方法使之成为可能）：

<xsl:template match="/album">
  <ol>
    <xsl:apply-templates select="track"/>
  </ol>
</xsl:template>

<xsl:template match="track">
  <li><a href="{@id}"><xsl:apply-templates/></a></li>
<xsl:template>

恕我直言，这看起来更短，更重要。

我猜你的

    <xsl:for-each select="track">
       <li><xsl:apply-templates/></li>
    </xsl:for-each>

遍历所有带有 的 track 元素for-each，然后将默认规则应用于其后代。因此 的内容与模板具有for-each相同的上下文节点match="track"，因此match="track"模板永远不会匹配。

如果您真的想以for-each这种方式使用，您将需要在您的方法中更改以下两件事之一：

  1. 给模板添加一个name="track"属性match="track"，然后使用<xsl:call-template/>from里面for-each（我的想法，比Tim C's差）
  2. 使用Tim C的解决方案<xsl:apply-templates select="."/>。这样做的好处是避免命名并保持对曲目进行排序的可能性。
于 2009-10-25T10:28:44.210 回答
0

我认为使用应用模板和模板模式是更清洁的解决方案：

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>

  <xsl:template match="/">
    <body>
      <xsl:apply-templates select="album" mode="ol" />
    </body>
  </xsl:template>

  <xsl:template match="album" mode="ol">
    <ol>
      <xsl:apply-templates select="track" mode="li" />
    </ol>
  </xsl:template>

  <xsl:template match="track" mode="li">
    <li>
      <xsl:apply-templates select="." />
    </li>
  </xsl:template>

  <xsl:template match="track">
    <a href="{@id}">
      <xsl:value-of select="." />
    </a>
  </xsl:template>


</xsl:stylesheet>

结果是：

<body>
  <ol>
    <li>
      <a href="shove">Somebody To Shove</a>
    </li>
    <li>
      <a href="gold">Black Gold</a>
    </li>
    <li>
      <a href="train">Runaway Train</a>
    </li>
  </ol>
</body>
于 2009-10-26T12:15:32.347 回答
0

for-each 语句将上下文节点从专辑更改为曲目。默认情况下，apply-templates 调用将模板应用于上下文节点的子节点，在您的情况下，该子节点是 track 元素的子节点。因此，与“track”匹配的模板永远不会被击中。

于 2009-10-29T17:44:57.527 回答