8

我在 oracle 代码块中使用集合，因为没有表变量（如在 MS SQL Server 中）。

DECLARE
    TYPE I_NAME IS TABLE OF NVARCHAR2(512);     
    I_ITEMNAME      I_NAME := I_NAME(); 
BEGIN

我正在使用“BULK COLLECT INTO I_ITEMNAME”来填充收藏。
我想在 SELECT 查询的 WHERE 子句中使用此集合，但找不到执行此操作的方法。目前我正在使用 FOR 循环并一项一项地获取项目。
我如何在 WHERE 子句中直接使用集合，例如

从 TBL 中选择 * I_ITEMNAME 中的 COL？

谢谢，

4

1 回答 1

17

您不能在 SQL 子句中使用本地声明的集合：

declare
    type i_name is table of nvarchar2(512);
    i_itemname i_name := i_name();
    c number;
begin
    select distinct owner bulk collect into i_itemname from all_objects;
    dbms_output.put_line(i_itemname.count);
    select count(*) into c
    from all_tables
    where owner in (select * from table(i_itemname));
    dbms_output.put_line(c);
end;
/

    where owner in (select * from table(i_itemname));
                                        *
ERROR at line 10:
ORA-06550: line 10, column 41:
PLS-00642: local collection types not allowed in SQL statements
ORA-06550: line 10, column 35:
PL/SQL: ORA-22905: cannot access rows from a non-nested table item
ORA-06550: line 8, column 5:
PL/SQL: SQL Statement ignored

但是如果它是在模式级别声明的，你可以这样做，本质上是让 SQL 知道类型，而不仅仅是 PL/SQL：

create type i_name is table of nvarchar2(512);
/

Type created.

declare
    i_itemname i_name := i_name();      
    c number;
begin 
    select distinct owner bulk collect into i_itemname from all_objects;
    dbms_output.put_line(i_itemname.count);
    select count(*) into c from all_tables
    where owner in (select * from table(i_itemname));
    dbms_output.put_line(c);
end;
/

No errors.
18
128

PL/SQL procedure successfully completed.

您还可以加入table构造而不是使用子查询：

...
    select count(*) into c
    from table(i_itemname) t
    join all_tables at on at.owner = t.column_value;
...

我不太清楚你是什么东东。（如果您没有将集合用于其他任何用途，最好只加入原始数据，但我认为集合存在是有原因的）。

正如@haki 在评论中提到的，你也可以这样做：

...
    select count(*) into c
    from all_tables
    where owner member of (i_itemname);
...

...只要i_name和您比较的列是相同的类型。在我的示例中，它找到零行，因为我试图与 进行比较nvarchar2，varchar2但如果重新定义i_name为，则会找到匹配项varchar2(512)。在你的情况下大概tab.col是nvarchar2无论如何。

于 2013-04-24T07:28:13.167 回答