1

作为背景，我在我的应用程序中使用 Grails v2.2.1 和 Searchable 插件 (v0.6.4)，尽管在配置 Lucene 方面我是新手。

日志显示搜索需要 26 毫秒，但罗盘事务大约需要 15 秒才能返回：

2013-04-23 00:40:34,269 DEBUG grails.plugin.searchable.internal. compass.search.DefaultSearchMethod - query: [+kind:band +name:snoop], [4] hits, took [26] millis

2013-04-23 00:40:49,965 DEBUG org.compass.core.transaction.LocalTransaction - Committing local transaction on thread [http-bio-8080-exec-10] Compass [1176020804] Session [2089649487]

与 Lucene 相比，这似乎是 Compass 的问题，因为查询执行速度很快，但 Compass 映射将我的 Java 进程固定在接近 100% CPU 并且挂起时间过长。

我索引了大约 3500 个域对象，我的域模型如下所示：我尝试仅索引字段名称和 id，但通过 Luke 看到它似乎映射了域中的所有内容。

package com.bandbot

class Band {
    def slugGeneratorService
    static searchable = {
        mapping {
            spellCheck "exclude"
            only: ['name', 'id']
        }
    }
    String name
    String biography
    String profileImage
    String slug
    String similarBands // this will store bands/url/pic in the form of Kanye West::url::img.png~Queen::url::img.png
    boolean onTour // is this band currently touring? (Info from lastfm)
    String mbid // This band's MusicBrainz ID see @ http://musicbrainz.org/doc/MusicBrainz_Identifier
    String bandUrl
    String lastFMUrl // stores the lastfm url
    Date dateOfInception
    Date dateDisbanded
    Date lastUpdated

    static belongsTo = [Genre, BandbotUser]

    static hasMany = [ events : Event, genres : Genre ]

    def beforeInsert() {
        lastUpdated = new Date()
        this.slug = slugGeneratorService.generateSlug(this.class, "slug", name)
    }

    def beforeUpdate() {
        lastUpdated = new Date()
        if (isDirty('name')) {
            this.slug = slugGeneratorService.generateSlug(this.class, "slug", name)
        }
    }

    static constraints = {
        name(nullable: false, blank: false, unique: true)
        slug(nullable: true)
        bandUrl(nullable: true)
        dateDisbanded(nullable: true)
        mbid(nullable: true)
        dateOfInception(nullable: true)
        biography(nullable: true)
        similarBands(nullable: true)
        lastUpdated(nullable: true)
        lastFMUrl(nullable: true)
        kind( display: false )
    }
    static mapping = {
        onTour defaultValue: false
        biography type: 'text'
        similarBands type: 'text'
    }

    String toString(){name}

}

我的控制器中的乐队搜索逻辑：

def search() {
    if (!params.q?.trim()) {
        return [:]
    }
    try {
        def searchResult


        if (params.sort) {
            searchResult = searchableService.search(
                    params.q.trim(),
                    [offset: params.offset ? params.int('offset') : 0,
                            max: params.max ? params.int('max') : 10,
                    sort: params.sort, order: params.order? params.order : 'asc']
                    )
        }
        else {
            searchResult = searchableService.search(
                    params.q.trim(),
                    [offset: params.offset ? params.int('offset') : 0,
                            max: params.max ? params.int('max') : 10]
                    )
        }

        return [searchResult: searchResult, params: params]

    } catch (SearchEngineQueryParseException ex) {
        return [parseException: true, params: params]
    }

}

任何想法将不胜感激。这是我的一个自学项目，我真的很想以正确的方式进行搜索。:) 谢谢，凯文

4

1 回答 1

2

在我正在开发的最近的 Grails 应用程序上使用可搜索插件时，我遇到了同样的问题。我有两个域对象，具有一对多关系，我正在索引以进行搜索。为简单起见，我只是展示了域对象及其字段和关系。我没有显示任何映射或约束信息。这是我原来的课程

class CodeValue{
    static searchable ={
        only:['value', 'description']
        value boost: 2.0
    }
    String value
    String description
    static belongsTo = [codeset: CodeSet]
}
class CodeSet{
    static searchable ={
        only:['name', 'description']
        name boost: 2.0
    }

    String name
    String description
    static hasMany = [codeValues:CodeValue]
}

搜索 CodeValues 的时间超过 17 秒。我确实索引了超过 1000 个 CodeValue 对象，但是 17 秒的搜索时间是不可接受的。我找出了导致搜索时间缓慢的原因，这似乎与 Grails Searchable 插件中内置的 Compass 功能有关。

作为搜索的一部分，所有匹配的对象都被编组到索引中。对于 100 的一组域对象，执行此编组的时间并不算太糟糕，但是，当您进入 1000 时，它需要大量的时间。也许时间也与被编组的对象的复杂性有关？无论如何，我找到了一个和我有类似问题的人的博客文章。

http://webcache.googleusercontent.com/search?q=cache:lebHKgX2yXUJ:blog.hououji.info/archives/165+&cd=10&hl=en&ct=clnk&gl=us

总结这篇文章，当他搜索 1000 多个对象时，搜索时间大于 15 秒。就像我正在经历的一样。

他提到了两件事：

1）将“supportUnmarshall”选项设置为false，默认值为true，在域对象的“静态可搜索”配置中。通过设置此选项，搜索匹配不会编组到索引中，但是搜索时间非常快。将此选项设置为 false 的缺点是结果将不包含从索引中解组的对象，并且您必须使用作为搜索结果的一部分返回的 id 从数据库中获取匹配的域对象。你会认为这会很糟糕，但事实并非如此，使用这种方法，我的搜索结果实际上显示得比以前快得多。这是有关设置 supportUnmarshall 选项的信息的 URL http://grails.org/Searchable+Plugin+-+Mapping+-+Class+Mapping。它是“选项”部分中的最后一个选项。

2）在Searchable.groovy配置文件的defaultMethodOptions中启用“reload”。因此，在 Searchable.groovy 文件中添加如下内容：

defaultMethodOptions = [
    search: [reload: true, escape: false, offset: 0, max: 25, defaultOperator: "and"],
    suggestQuery: [userFriendly: true]
]

您将需要添加 Searchable Config 插件来更新此值。添加和编辑 Searchable.groovy 配置文件的详细信息可以在 Grail Searchable 插件的网页上找到。因为我没有足够高的声誉。我不能发布两个以上的链接，因此您需要访问 Grails Searchable 插件的网页，并查找有关如何安装 Searchable Config Plugin 的文档。

举一个性能改进的例子。以前，对 CodeValues 的搜索需要 17 多秒才能完成。它们现在在 0.002 秒内完成。

我写的最终代码是这样的：

class CodeValue{
    static searchable ={
        only:['value', 'description']
        value boost: 2.0
        supportUnmarshall false
    }
    String value
    String description
    static belongsTo = [codeset: CodeSet]
}
class CodeSet{
    static searchable ={
        only:['name', 'description']
        name boost: 2.0
        supportUnmarshall false
    }

    String name
    String description
    static hasMany = [codeValues:CodeValue]
}
于 2014-03-25T14:48:49.480 回答