sql - 拆分并计算与分隔符合并的值

Question

我在一个单元格中有 a|b|c|d|.. 值。如何通过在分隔符的帮助下拆分它来计算所有调用中 b 的总出现次数

Answer 1

如果需要计算出现次数，可以使用这个（SQL Server）：

SELECT LEN(yourColumn) - LEN(REPLACE(yourColumn, 'b', '')) FROM yourTable

Answer 2

我在 SQL-Server 2005 上并使用此Split功能：

SELECT split.Item, count=Count(*)
FROM dbo.Foo f
CROSS APPLY dbo.Split(f.ColName, '|')split
GROUP BY split.Item
Having split.Item='b'

这里的表值函数：

CREATE FUNCTION [dbo].[Split]
(
    @ItemList NVARCHAR(MAX), 
    @delimiter CHAR(1)
)
RETURNS @IDTable TABLE (Item VARCHAR(50))  
AS      

BEGIN    
    DECLARE @tempItemList NVARCHAR(MAX)
    SET @tempItemList = @ItemList

    DECLARE @i INT    
    DECLARE @Item NVARCHAR(4000)

    SET @tempItemList = REPLACE (@tempItemList, ' ', '')
    SET @i = CHARINDEX(@delimiter, @tempItemList)

    WHILE (LEN(@tempItemList) > 0)
    BEGIN
        IF @i = 0
            SET @Item = @tempItemList
        ELSE
            SET @Item = LEFT(@tempItemList, @i - 1)
        INSERT INTO @IDTable(Item) VALUES(@Item)
        IF @i = 0
            SET @tempItemList = ''
        ELSE
            SET @tempItemList = RIGHT(@tempItemList, LEN(@tempItemList) - @i)
        SET @i = CHARINDEX(@delimiter, @tempItemList)
    END 
    RETURN
END  

演示