3

我正在写作业（CIS194 Haskell 课程）。

我必须将以下递归函数重写为管道函数（没有明显的递归）。

fun2 :: Integer -> Integer
fun2 1 = 0
fun2 n 
    | even n = n + fun2 ( n ‘div‘ 2 )
    | otherwise = fun2 (3 * n + 1)

我的第一次尝试是在这里：

fun2''' = sum 
          . (filter (even)) 
          . unfoldr (\x -> if (even x) 
                          then Just (x, x `div` 2)
                          else if (x==1) then Nothing 
                               else Just (x, x * 3 + 1))

这是一个正常的解决方案还是很奇怪？

我怎样才能fun2更好地重写？

takeWhile现在我尝试使用和编写版本iterate

我的第二次尝试：

fun2'' :: Integer -> Integer
fun2'' = sum 
         . (filter even) 
         . takeWhile (/=1) 
         . iterate (\x -> if even x 
                          then x `div` 2
                          else x * 3 + 1 )

我until现在版本有点问题。

4

2 回答 2

2

看起来不错，这里唯一在 Haskell 中有点危险的是else if. 在这种情况下，它可以用应用风格很好地重写：

{-# LANGUAGE TupleSections     #-}

import Control.Applicative
import Control.Monad (guard)

fun2''' = sum 
          . filter even
          . unfoldr ( \x -> fmap (x,) $
                   x`div`2 <$ guard(even x)
               <|> x*3 + 1 <$ guard( x/=1 )
             )
于 2013-04-21T16:57:01.070 回答
1

嵌套ifs 现在可以用多路 IF编写：

g :: Integer -> Integer
g = sum . 
     unfoldr (\x-> 
          if | even x    -> Just (x, x `div` 2) 
             | x==1      -> Nothing 
             | otherwise -> Just (0, x * 3 + 1))

或者您可以定义自己的if运算符，

(??) t (c,a) | t = c | otherwise = a

g = sum . unfoldr (\x-> even x ?? (Just (x, x `div` 2) ,
                        (x==1) ??  (Nothing, Just (0, x * 3 + 1))))

until与, withsum和filter融合到其中的相同功能：

g = fst . until ((==1).snd) 
            (\(s,n) -> if even n then (s+n,n`div`2) else (s,3*n+1)) 
    . ((,)0)

或者

g = sum . filter even . f

f :: Integer -> [Integer]
f = (1:) . fst . until ((==1).snd) 
            (\(s,n) -> if even n then (n:s,n`div`2) else (n:s,3*n+1)) 
    . ((,)[])

最后一个函数f显示给定输入数字的整个 Collat​​z 序列，反转。

于 2013-04-22T11:12:35.773 回答