3

我有一个 xml 文件，如下所示：

<Messages>
   error message 1

   error message 2 
</Messages>

我希望输出为：

Error 1: 
error message 1

Error 2:
error message 2

我正在使用 xslt 1.0，我尝试过：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html" omit-xml-declaration="yes"/>

<xsl:template match="Messages">
    <h3>Error 1:</h3>
    <xsl:value-of select="substring-before(./text(), '&#10;')"/>
    <h3>Error 2:</h3>
    <xsl:value-of select="substring-after(./text(), '&#10;')"/>
</xsl:template>
</xsl:stylesheet>

但它没有给我任何回报......有人可以帮我解决这个问题吗？谢谢！

4

2 回答 2

1

如果我必须使用 XSLT 1.0，我会写一个这样的两遍转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common">
 <xsl:output method="text"/>

 <xsl:template match="/*">
  <xsl:variable name="vrtfPass1">
      <xsl:copy><xsl:apply-templates/></xsl:copy>
  </xsl:variable>

  <xsl:apply-templates select=
  "ext:node-set($vrtfPass1)/*/line
       [preceding-sibling::node()[1][self::text() and normalize-space()]]"/>
 </xsl:template>

 <xsl:template match="/*/text()" name="markUp">
  <xsl:param name="pText" select="."/>

  <xsl:if test="normalize-space($pText)">
      <xsl:value-of select="substring-before(concat($pText,'&#xA;'), '&#xA;')"/>
      <line/>
      <xsl:call-template name="markUp">
        <xsl:with-param name="pText" select="substring-after($pText,'&#xA;')"/>
      </xsl:call-template>
  </xsl:if>
 </xsl:template>

 <xsl:template match="line">
Error: <xsl:value-of select="concat(position(), '&#xA;')"/>
  <xsl:value-of select="normalize-space(preceding-sibling::node()[1])"/>
  <xsl:text>&#xA;</xsl:text>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<Messages>
   error message 1

   error message 2
</Messages>

产生了想要的正确结果：

Error: 1
error message 1

Error: 2
error message 2
于 2013-04-18T04:24:16.670 回答
1

您可以使用此递归模板来实现此目的：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html" omit-xml-declaration="yes"/>

  <xsl:template match="Messages" name="outputError">
    <xsl:param name="index" select="1"/>
    <xsl:param name="source" select="text()"/>
    <xsl:variable name="thisLine" select="normalize-space(substring-before($source, '&#10;'))"/>
    <xsl:variable name="theRest" select="substring-after($source, '&#10;')"/>
    <xsl:choose>
      <xsl:when test="$thisLine">
        <h3>Error <xsl:value-of select="$index"/>:</h3>
        <span><xsl:value-of select="$thisLine"/></span>
        <xsl:call-template name="outputError">
          <xsl:with-param name="index" select="$index + 1"/>
          <xsl:with-param name="source" select="$theRest"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:when test="$theRest">
        <xsl:call-template name="outputError">
          <xsl:with-param name="index" select="$index"/>
          <xsl:with-param name="source" select="$theRest"/>
        </xsl:call-template>
      </xsl:when>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

我将实际错误包装在一个<span>元素中只是为了清楚地将它们与空白区分开来，如果您愿意，您当然可以使用 a <p>，<div>或者根本没有元素。

于 2013-04-18T15:52:05.557 回答