ms-access - ADO 加速打开表访问

Question

根据写入数据的速度，对于 rs.AddNew 和 rs.Update，使用 ADO 和 Access 打开表的最佳方法是什么？

我需要使用特定的光标或特定的方法吗？

我使用从 VB6 到 Jet 的 ADO 连接。

Answer 1

我的两个建议是：

1. 打开 RecordsetadOpenStatic以尽量减少尝试跟踪其他用户可能对表进行的更改的开销。

2. .AddNew通过cn.BeginTrans在批量插入之前和cn.CommitTrans之后在事务中包装多个操作。

编辑

在回应@Bob77 的评论时，他说：

围绕一系列任意更新操作抛出 Begin/End Trans 不会提供任何内在的性能优势，并且在大多数情况下会使事情变得更糟。

以下 VBScript 测试结果清楚地表明，在事务中包装一批插入可以大大提高使用 Jet/ACE 数据库时的性能。

Option Explicit
Dim con, rst, t0, i, n, s
Const adUseClient = 3
Const adOpenStatic = 3
Const adLockOptimistic = 3
Const useTransaction = False

t0 = Timer
n = 1000
Set con = CreateObject("ADODB.Connection")
con.CursorLocation = adUseClient
con.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=Y:\adoTimeTest.accdb;"
Set rst = CreateObject("ADODB.Recordset")
rst.Open "SELECT * FROM tbl", con, adOpenStatic, adLockOptimistic
If useTransaction Then
    con.BeginTrans
End If
For i = 1 to n
    rst.AddNew
    rst("ItemName").Value = "Item_" & i
    rst("SeqNo").Value = i
    rst.Update
Next
If useTransaction Then
    con.CommitTrans
End If
rst.Close
Set rst = Nothing
con.Close
Set con = Nothing
s = "Added " & n & " rows in " & Round(Timer - t0, 1) & " seconds with"
If Not useTransaction Then
    s = s & "out"
End If
s = s & " transaction."
Wscript.Echo s

表 [tbl] 的结构是

ID       - AutoNumber, Primary Key
ItemName - Text(255), Indexed (duplicates OK)
SeqNo    - Long Integer, Indexed (no duplicates)

测试 1：useTransaction = False

[tbl] 表是空的，并且 .addcb 文件已被新压缩。

Y:\>cscript /nologo adoTimeTest.vbs
Added 1000 rows in 103.9 seconds without transaction.

测试 2：useTransaction = True

[tbl] 表已被清空，并且 .addcb 文件已重新压缩。

Y:\>cscript /nologo adoTimeTest.vbs
Added 1000 rows in 4.9 seconds with transaction.

编辑

针对@Bob77 的后续评论：

我会再次尝试打开数据库以进行独占访问。

使用 ODBC 和独占访问的附加测试：

con.Open "Driver={Microsoft Access Driver (*.mdb, *.accdb)};Dbq=Y:\adoTimeTest.accdb;Exclusive=1;Uid=admin;Pwd=;"

测试 3：useTransaction = False

[tbl] 表是空的，并且 .addcb 文件已被新压缩。

Y:\>cscript /nologo adoTimeTest.vbs
Added 1000 rows in 26.5 seconds without transaction.

测试 4：useTransaction = True

[tbl] 表已被清空，并且 .addcb 文件已重新压缩。

Y:\>cscript /nologo adoTimeTest.vbs
Added 1000 rows in 6.1 seconds with transaction.