11

我有以下存储电影和演员详细信息的 XML 文件：

<database
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:noNamespaceSchemaLocation="movies.xsd">

<movies>
    <movie movieID="1">
        <title>Movie 1</title>
        <actors>
            <actor actorID="1">
                <name>Bob</name>
                <age>32</age>
                <height>182 cm</height>
            </actor>
            <actor actorID="2">
                <name>Mike</name>
            </actor>
        </actors>
    </movie>
</movies>

</database>

如果actor元素包含多个子元素（在本例中是名称、年龄和身高），那么我想将其名称显示为超链接。

但是，如果actor元素只包含一个子元素（名称），那么它应该显示为纯文本。

XSLT：

<xsl:template match="/">
    <div>
      <xsl:apply-templates select="database/movies/movie"/>
    </div>
  </xsl:template>

  <xsl:template match="movie">
    <xsl:value-of select="concat('Title: ', title)"/>
    <br />
    <xsl:text>Actors: </xsl:text>
    <xsl:apply-templates select="actors/actor" />
    <br />
  </xsl:template>    

<xsl:template match="actor">
    <xsl:choose>
        <xsl:when test="actor[count(*) &gt; 1]/name">
            <a href="actor_details.php?actorID={@actorID}">
                <xsl:value-of select="name"/>
            </a>
            <br/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="name"/>
            <br/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

所以在这种情况下，Bob 应该显示为超链接，而 Mike 应该显示为纯文本。但是，我的页面将 Bob 和 Mike 都显示为纯文本。

4

1 回答 1

20

你的第一个xsl:when test is wrong here

<xsl:when test="actor[count(*) &gt; 1]/name">

你已经定位在一个演员元素上，所以这将寻找一个演员元素，它是当前演员元素的子元素，但什么也找不到。

你可能只想这样做

<xsl:when test="count(*) &gt; 1">

或者，您可以这样做

<xsl:when test="*[2]">

即，第二个位置是否有一个元素（当您只想检查是否有多个元素时，可以节省所有元素的计数），

或者您可能想检查当前的actor元素是否有name以外的元素？

<xsl:when test="*[not(self::name)]">

顺便说一句，最好将测试放在模板匹配中，而不是使用xsl:choose。

试试这个 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes" encoding="utf-8" omit-xml-declaration="no"/>

   <xsl:template match="/">
      <div>
         <xsl:apply-templates select="database/movies/movie"/>
      </div>
   </xsl:template>

   <xsl:template match="movie">
      <xsl:value-of select="concat('Title: ', title)"/>
      <br/>
      <xsl:text>Actors: </xsl:text>
      <xsl:apply-templates select="actors/actor"/>
      <br/>
   </xsl:template>

   <xsl:template match="actor">
      <xsl:value-of select="name"/>
      <br/>
   </xsl:template>

   <xsl:template match="actor[*[2]]">
      <a href="actor_details.php?actorID={@actorID}">
         <xsl:value-of select="name"/>
      </a>
      <br/>
   </xsl:template>
</xsl:stylesheet>

请注意，在这种情况下，XSLT 处理器应该首先匹配更具体的模板。

于 2013-04-15T18:38:02.320 回答