1

所以我试图让我的 Fortran 95 代码仅用于基本功能和程序定义。对于每行“意外”或“未分类”，我几乎都会得到一个错误。我想知道它是我的编译器（在 cygwin 终端中使用的 gfortran）还是我应该在文件的开头放一些东西？如果有人可以告诉我任何事情，那就在这里。

    double precision :: pi = 3.14159265359

    PROGRAM Diffraction
            write (*,*) sinc(0)
            write (*,*) sinc(pi)
            write (*,*) 1_Slit(0, 1, 550E-9)
    end PROGRAM Diffraction

    function SINC(angle) result(sinc)
    double precision :: sinc
    double precision :: angle
    if angle == 0.0 then
            sinc == 1
    else
            sinc = (sin(angle)/angle)
    endif
    end function SINC

    function I(angle, d, wl) result(I)
            double precision :: I_0 = 0.01
            double precision :: angle, d, wl, I
            A = (d * pi)/wl
            B = SIN(angle)
            I = I_0 * (SINC(A*B)**f2)
    return
    end function I

我编译的方式是：gfortran Diffraction.f95

4

1 回答 1

1

一般来说，将所有定义放在主程序或模块中是个好主意。所以你的“浮动”定义有点奇怪。

您的程序应该PROGRAM [name]以您使用的模块开头。在您的情况下，没有这样的模块。在此之后，编写IMPLICIT NONE. 这意味着，没有变量具有预定义的类型。I否则，每个以to开头的变量N都是 type INTEGER，而其他所有变量都是 type REAL。

下一部分是变量定义部分，在这里定义您的变量。（您示例中的第一行。）

在此之后，主要部分是执行代码的地方。

最后一部分是CONTAINS放置函数和子例程的部分，它可以使用程序中定义的每个变量（但这将是不好的实践......）。

所以你的例子（有一些更正）看起来像：

PROGRAM Diffraction
IMPLICIT NONE

double precision :: pi = 3.14159265359d0

  write (*,*) sinc(0.d0)
  write (*,*) sinc(pi)
  write (*,*) one_slit(0.d0, 1.d0, 550.d-9)

CONTAINS

  function SINC(angle) result(snc)
    double precision :: snc
    double precision :: angle

    if (angle == 0.d0) then
      snc = 1.d0
    else
      snc = (sin(angle)/angle)
    endif
  end function SINC

  function one_slit(angle, d, wl) result(I)
    double precision :: I0 = 0.01d0, A, B
    double precision :: angle, d, wl, I, f2=2.d0

      A = (d * pi)/wl
      B = SIN(angle)
      I = I0 * (SINC(A*B)**f2)
  end function one_slit

end PROGRAM Diffraction
于 2013-04-15T13:43:09.147 回答