4

我有一个TWebBrowser控件，它实现IDocHostUIHandler了通过IDispatch容器扩展 JavaScript 互操作的控制。这工作正常，除了我不知道如何将事件从 JavaScript 分派回 Web 浏览器控件。

扩展对象是一个基于TAutoIntfObjectlike in的容器this example。正如您在示例中看到的，与 Web 浏览器控件没有互操作性。理想情况下，我想在该扩展对象上实现事件，但我不知道如何TAutoIntfObject在我的 Web 浏览器控件中正确声明该对象。假设我有这个扩展对象：

type
  TZoomChangeEvent = procedure(Sender: TObject; ZoomLevel: Integer) of object;
  TOpenLayersExt = class(TAutoIntfObject, IOpenLayers)
  private
    FOnZoomChange: TZoomChangeEvent;
    // the ZoomChange method is invoked from JavaScript
    procedure ZoomChange(ZoomLevel: Integer); safecall;
  public
    property OnZoomChange: TZoomChangeEvent read FOnZoomChange write FOnZoomChange;
  end;

implementation

procedure TOpenLayersExt.ZoomChange(ZoomLevel: Integer);
begin
  if Assigned(FOnZoomChange) then
    FOnZoomChange(Self, ZoomLevel);
end;

像这样的TWebBrowser控件：

type
  TMapBrowser = class(TWebBrowser, IDocHostUIHandler)
  private
    // the extension object
    FExtObj: TOpenLayersExt;
    // IDocHostUIHandler::GetExternal method
    function GetExternal(out ppDispatch: IDispatch): HRESULT; stdcall;
    // this is the TOpenLayersExt.OnZoomChange event method implementation
    procedure OnZoomChange(Sender: TObject; Zoom: Integer);
  public
    // ordinary constructor
    constructor Create(AOwner: TComponent); override;
  end;

implementation

constructor TMapBrowser.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  // create extension object
  FExtObj := TOpenLayersExt.Create;
  // here the event method is properly binded; if I'd change the FExtObj type
  // to IDispatch with TOpenLayersExt(FExtObj) typecast, it wouldn't
  FExtObj.OnZoomChange := OnZoomChange;
end;

function TMapBrowser.GetExternal(out ppDispatch: IDispatch): HRESULT;
begin
  // the problem is that I don't know how to properly pass this object to the
  // ppDispatch parameter; if this GetExternal method is called second time,
  // the FExtObj seems to be released, but I don't get why
  ppDispatch := FExtObj as IDispatch;
  Result := S_OK;
end;

问题是，如果我将FExtObj对象声明为TOpenLayersExt，则绑定事件方法，但FExtObj对象引用似乎在第一个扩展对象方法调用（来自 JavaScript）之后被释放。

如果我将其声明为IDispatch，则在 JavaScript 函数调用后不会释放引用，但OnZoomChange不会绑定事件。

很难在此处发布完整的代码，因为它由更多部分组成，here is a complete project由 Delphi 7 制作。

所以我的问题是，如何TAutoIntfObject在 Web 浏览器控件中使用来自扩展对象的事件；如何声明扩展对象，以便我能够处理来自 Web 浏览器控件的事件并将其传递给IDocHostUIHandler::GetExternal方法参数，仍然保持接口对象引用？

4

1 回答 1

6

使用引用计数，即。保持 FExtObj 作为对接口的引用，而不是对象：

  private
    // the extension object
    FExtObj: IDispatch;

...

constructor TMapBrowser.Create(AOwner: TComponent);
var
  AExtObj: TOpenLayersExt;
begin
  inherited Create(AOwner);
  // create extension object
  AExtObj := TOpenLayersExt.Create;
  AExtObj.OnZoomChange := OnZoomChange;
  FExtObj := AExtObj as IDispatch;
end;

destructor TMapBrowser.Destroy;
begin
  FExtObj := nil;
  inherited Destroy;
end;
于 2013-04-12T15:49:51.043 回答