5

我在 grails 中定义了递归域类：

class Work {

  String code
  String title
  String description
  static hasMany = [subWorks:Work]
  static mappedBy = [subWorks: 'parentWork']

  Work getRootWork(){
    if(parentWork) return parentWork.getRootWork()
      else return this
  }

  boolean isLeafWork(){
    return subWorks.isEmpty()
  }

  boolean isRootWork(){
    return !parentWork
  }

我有一个作品列表，但尚未建立层次结构。结构如下：

def works = [new Work(code:'A', title:'TitleA'), 
    new Work(code:'B', title:'TitleB'), 
    new Work(code:'A.1', title:'Titile A.1'), 
    new Work(code:'B.1', title:'Title B.1'),
    new Work(code:'B.2', title:'Title B.2'),
    new Work(code:'B.3', title:'Title B.3'), 
    new Work(code:'B.2.2', title:'Title B.2.2'),
    new Work(code:'B.2.3', title:'Title B.2.3'),
    new Work(code:'A.1.1', title:'Title A.1.1'),
    new Work(code:'A.1.2', title:'Title A.1.2'),]

我需要的是根据提示的代码建立这些作品之间的层次关系。例如 A.1 是 A 的第一个子工作；B.1.1 是 B.1 工作的第一个孩子，其父母是 B 工作。我知道 Groovy 支持递归闭包来构建这种层次结构。如何使用 Groovy 递归闭包实现我的目标，例如 Groovy 官方文档中的 JN2515 斐波那契数示例？非常感谢！

4

2 回答 2

3

像这样...？

def root = new Work(code:'*', title:'ROOT')

def build 

build = { p, list ->
  list.groupBy{it.code.split('\\.').first()}.each{ el, sublist ->
    el = sublist[0]        
    el.parentWork = p
    if(sublist.size()>1){
        build(el, sublist[1..-1] )
    }
  }

}
build(root, works.sort{it.code.length()})

如果我没有错，即使是这种匿名形式也可以工作

def root = new Work(code:'*', title:'ROOT')

{ p, list ->
  list.groupBy{it.code.split('\\.').first()}.each{ el, sublist ->
    el = sublist[0]        
    el.parentWork = p
    if(sublist.size()>1){
      call(el, sublist[1..-1] )
    }
  }

}(root, works.sort{it.code.length()})
于 2013-04-12T12:06:51.803 回答
1

我对 Grails 有点生疏，但我似乎记得它以一种智能的方式管理映射集合，这样如果你这样做：work1.parentWork = work2thenwork1 in work2.subWorks将验证。如果是这种情况，您只需parentWork为每项工作设置 ，您无需为此进行任何复杂的计算： 的父工作X.Y.Z将为X.Y， 的父工作X将为无：

def works = [new Work(code:'A', title:'TitleA'),
    new Work(code:'B', title:'TitleB'),
    new Work(code:'A.1', title:'Titile A.1'),
    new Work(code:'B.1', title:'Title B.1'),
    new Work(code:'A.1.1', title:'Title A.1.1')]

def worksByCode = works.collectEntries { [it.code, it] }

works.each {
    if (it.code.contains('.')) {
        def parentCode = it.code[0..it.code.lastIndexOf('.') - 1]
        it.parentWork = worksByCode[parentCode]
    }
}
于 2013-04-12T12:51:18.893 回答