4

VB.NET 2010 - 我有一个 RichTextbox，用户可以在其中手动输入数据或从其他来源复制/粘贴。数据完成后，他点击 go 并突出显示几个关键词。我的问题是，如果他从另一个来源复制/粘贴，格式也会被复制。好吧，有时外部源有白色字体，而我的文本框有白色背景，所以看起来他什么也没粘贴，而且他一次又一次地粘贴。

我正在寻找一种将粘贴操作截获到文本框中的方法，以便我可以将该文本粘贴为纯 ASCII 而无需格式化。

尝试使用 KeyDown 后进行编辑

Private Sub txtRch_KeyDown(sender As Object, e As System.Windows.Forms.KeyEventArgs) Handles txtRch.KeyDown
    If e.Modifiers = Keys.Control AndAlso e.KeyCode = Keys.V Then
        With txtRch
            Dim i As Integer = .SelectionStart          'cache the current position
            .Select(0, i)                               'select text from start to current position
            Dim s As String = .SelectedText             'copy that text to a variable
            .Select(i, .TextLength)                     'now select text from current position to end
            Dim t As String = .SelectedText             'copy that text to a variable
            Dim u As String = s & Clipboard.GetText(TextDataFormat.UnicodeText) & t 'now concatenate the first chunk, the new text, and the last chunk
            .Clear()                                    'clear the textbox
            .Text = u                                   'paste the new text back into textbox
            .SelectionStart = i                         'put cursor back to cached position
        End With

        'the event has been handled manually
        e.Handled = True
    End If
End Sub

这似乎有效，我所有的文本都被保留了，而且都是 ASCII。我想如果我想更进一步，我也可以使用我的 RichTextbox 的字体和前景色，选择所有文本，然后将字体和前景色分配给选择。

4

1 回答 1

7

在大多数情况下，检查 KeyDown 事件以及使用临时 RichTextBox 来修改传入文本应该足够好：

Private Sub RichTextBox1_KeyDown(sender As Object, e As KeyEventArgs) _
                                 Handles RichTextBox1.KeyDown
  If e.Modifiers = Keys.Control AndAlso e.KeyCode = Keys.V Then

    Using box As New RichTextBox
      box.SelectAll()
      box.SelectedRtf = Clipboard.GetText(TextDataFormat.Rtf)
      box.SelectAll()
      box.SelectionBackColor = Color.White
      box.SelectionColor = Color.Black
      RichTextBox1.SelectedRtf = box.SelectedRtf
   End Using

   e.Handled = True
  End If
End Sub

注意：缺少任何错误检查。

于 2013-04-11T21:01:59.050 回答