好的，从这里关于这个问题的有用指针，以及我在其他地方提出的其他一些问题，我认为对于任何想要从 Excel 电子表格中提取数据作为动态范围或静态范围的人来说，我有一个相当简单的解决方案，其中Excel 中的数据不在单元格 A1 中开始。
这两个示例都使用按钮来启动代码。您显然不必这样做，但如果这样做，您将需要创建一个表单和按钮，然后从按钮上运行代码生成器，并用下面您需要的任何解决方案替换该代码。
动态范围：
请注意，此动态范围示例假定 Excel 中的单元格范围始终从相同的最左上角位置开始，并且列数始终相同 - 即唯一动态的是底部行数你的细胞范围。
您需要根据自己的设置换出的参考资料：
C:\Users\Matt\Desktop\ExcelFile1.xls替换为 Excel 文件的完整路径
Dynamic替换为 Excel 文件中包含的工作表名称
A14:A2000替换为您要测试的范围以查看有多少非空单元格。这个范围应该： 从列标题所在的数据行开始；覆盖您要导入的数据中永远不会有空单元格条目的列；覆盖的范围足够大，以至于它总是会超过 Excel 电子表格中包含实际数据的行数。
ExcelDynamicRangeData替换为您想要在 Access 中调用包含从 Excel 范围中提取的数据的表的任何内容。
Dynamic!A14:EL替换为工作表的名称、Excel 范围的最顶部/最左侧的单元格引用和最右侧的列字母。不要包括最底部/最右侧的行号，因为这是需要动态的，因此numberofrows稍后将其分配给该范围的末尾并将其连接到该范围的末尾。
numberofrows = 13 ...将 13 替换为列标题开始位置上方的行数。例如，如果您的列标题从第 4 行开始，则此数字需要为 3。
Command0替换为用于启动所有此代码的按钮的名称。
Sub ImportDataFromRange()
' Assign the Excel Object
Dim excelapp As Object
Set excelapp = CreateObject("excel.application")
' Assign the workbook
Dim wb As Object
Set wb = excelapp.Workbooks.Open("C:\Users\Matt\Desktop\ExcelFile1.xls")
' Assign the result of your CountA function used in the next line
Dim numberofrows As Integer
' Get the bottom-most row number needed to complete our dynamic range address
numberofrows = 13 + excelapp.Application.CountA(wb.worksheets("Dynamic").Range("A14:A2000"))
' Delete any previous access table, otherwise the next line will add an additional table each time it is run
DoCmd.DeleteObject acTable, "ExcelDynamicRangeData"
' Import data from Excel using a range that now knows where bottom row number is
DoCmd.TransferSpreadsheet acLink, acSpreadsheetTypeExcel9, "ExcelDynamicRangeData", "C:\Users\Matt\Desktop\ExcelFile1.xls", True, "Dynamic!A14:EL" & numberofrows
' Close and clean
wb.Close
Set wb = Nothing
excelapp.Quit
Set excelapp = Nothing
End Sub
Private Sub Command0_Click()
ImportDataFromRange
End Sub
静态范围：
这要简单得多，因为无需打开 Excel 工作簿即可CountA对数据应用函数。
您需要根据自己的设置换出的参考资料：
C:\Users\Matt\Desktop\ExcelFile2.xls替换为 Excel 文件的完整路径
ExcelStaticRangeData替换为您想要在 Access 中调用包含从 Excel 范围中提取的数据的表的任何内容。
Static!A14:EL20替换为工作表的名称，以及要导入的 Excel 中单元格的完整范围地址。由于此方法描述了如何从 Excel 中获取静态数据范围以访问 Excel 中的数据，因此您要导入的数据永远不应超出此范围。
Command0替换为用于启动所有此代码的按钮的名称。
Sub ImportDataFromRange()
' Delete any previous access table, otherwise the next line will add an additional table
DoCmd.DeleteObject acTable, "ExcelStaticRangeData"
' Import data from Excel using a static range
DoCmd.TransferSpreadsheet acLink, acSpreadsheetTypeExcel9, "ExcelStaticRangeData", "C:\Users\Matt\Desktop\ExcelFile2.xls", True, "Static!A14:EL20"
End Sub
Private Sub Command0_Click()
ImportDataFromRange
End Sub
注意：
两种方法中的acSpreadsheetTypeExcel9位指的是您正在导入的 Excel 文件的版本；在我的示例中，我正在导入 Excel 2000 格式；您可能正在导入不同版本的 Excel，因此请参阅此以查看您需要在代码中引用哪个版本；.xlsx文件未列出，但应该是acSpreadsheetTypeExcel12Xml.
我的示例将数据作为源数据的活动链接引入 Access。如果您有大量数据，您可能会发现将数据实际导入并存储到 Access 中会更好，因为链接可能会导致一些性能问题。如果是这种情况，请换掉acLink。acImport
如果您尚未在 Access 中手动创建一个空白表（在代码中引用了相同的表名），那么您要么需要这样做，要么DoCmd.DeleteObject acTable, "yourAccessTable"在第一次运行代码时注释掉，然后再恢复这部分.
可能还有更多的事情可以做 - 即，如果您的数据源具有不同数量的列，则调整 CountA 函数以考虑动态的列数。
再次感谢@david-zemens、@gord-thompson 以及其他 StackoverFlow 用户帮助我实现这一点 - 这对我和希望其他人都非常有用。