0

在这个问题上我真的用尽了我所有的知识，所以我希望我的同龄人能够帮助我？

我正在构建一个混音器，它有五个轨道，每个轨道都有一个音量滑块和静音按钮。静音按钮而不是每个轨道的开始/停止按钮的原因是，无论何时引入样本，所有样本都将同步。该应用程序具有全局启动、停止和暂停按钮，它们都正常工作，但我无法让音量滑块和静音按钮在单个声道上协同工作。如果我注释掉另一个功能，音量滑块和静音按钮都可以工作，但是当两者都在播放时，只有音量滑块工作。我猜测存在冲突，因为我有两个使用 soundTransform 对象/类的单独变量，但也许您可以对这个难题有所了解？这是我的一首曲目的代码...任何帮助。

var mySound1:Sound1 = new Sound1();
var myChannel1:SoundChannel = new SoundChannel();
var volumeAdjust1:SoundTransform = new SoundTransform();
volumeAdjust1.volume = 0;

mute_btn1.stop();
mute_btn1.addEventListener(MouseEvent.CLICK,togglemute_btn1);

var Mute1:Boolean = false;

function togglemute_btn1(event:MouseEvent)
{
    if (Mute1)
    {
        mute_btn1.gotoAndStop(1);
        volumeAdjust1.volume = 1;
        myChannel1.soundTransform = volumeAdjust1;
        Mute1 = false;
    }
    else
    {
        mute_btn1.gotoAndStop(2)
        volumeAdjust1.volume = 0;
        myChannel1.soundTransform = volumeAdjust1;
        Mute1 = true;
    }

}

/*if the section below is commented out then the mute_btn1 works fine
otherwise the volume slider functions are dominent*/
var dragging1:Boolean = false;
var mySliderLength1:uint = 300;
var boundingBox1:Rectangle = new Rectangle(0,0,0,mySliderLength1);
slider_mc1.knob_mc1.addEventListener(MouseEvent.MOUSE_DOWN, dragKnob1);
stage.addEventListener(MouseEvent.MOUSE_UP, releaseKnob1);
slider_mc1.knob_mc1.buttonMode = true;

function dragKnob1(myEvent:Event):void
{
    slider_mc1.knob_mc1.startDrag(false, boundingBox1);
    dragging1 = true;
    slider_mc1.knob_mc1.addEventListener(Event.ENTER_FRAME, adjustVolume1);
}

function releaseKnob1(myEvent:Event):void
{
    if (dragging1)
    {
        slider_mc1.knob_mc1.stopDrag();
        dragging1 = false;
    }
}

function adjustVolume1(myEvent:Event):void
{
    var myVolume1:Number = slider_mc1.knob_mc1.y / mySliderLength1;
    var myTransform1:SoundTransform = new SoundTransform(myVolume1);

    if (myChannel1!=null)
    {
        myChannel1.soundTransform = myTransform1;
    }
}
4

2 回答 2

1

我相信您的问题是每次单击鼠标时都会不断添加 Enter_Frame 侦听器，但它永远不会被删除。因此，即使您松开旋钮，adjustVolume1 函数仍会被调用（在调用静音切换函数后，这会破坏静音函数调用在帧上所做的任何事情）。

因此，鉴于当前状态，我认为我将如何处理这个问题是将 Enter_Frame 侦听器添加到 dragKnob 函数之外，并且在 adjustVolume1 处理程序中只需检查 dragging1 是否为真，否则就返回。

slider_mc1.knob_mc1.addEventListener(Event.ENTER_FRAME, adjustVolume1);

function dragKnob1(myEvent:Event):void
{
...
}

function adjustVolume1(myEvent:Event):void
{
   if(!dragging1)
       return;
   ...
}
于 2013-04-10T04:40:07.277 回答
1

你应该在你Mute1的那个监听器中检查你的变量，如果静音，那么音量=0，否则计算音量。确实，请在stopDrag()调用点删除您的输入帧侦听器。

function dragKnob1(myEvent:Event):void
{
    slider_mc1.knob_mc1.startDrag(false, boundingBox1);
    dragging1 = true;
    slider_mc1.knob_mc1.addEventListener(Event.ENTER_FRAME, adjustVolume1);
}

function releaseKnob1(myEvent:Event):void
{
    if (dragging1)
    {
        slider_mc1.knob_mc1.stopDrag();
        dragging1 = false;
        slider_mc1.knob_mc1.removeEventListener(Event.ENTER_FRAME, adjustVolume1);
        // ^ this line added
    }
}

function adjustVolume1(myEvent:Event):void
{
    if (Mute1) return;
    // ^ and this line added
    var myVolume1:Number = slider_mc1.knob_mc1.y / mySliderLength1;
    var myTransform1:SoundTransform = new SoundTransform(myVolume1);

    if (myChannel1!=null)
    {
        myChannel1.soundTransform = myTransform1;
    }
}
于 2013-04-10T06:18:27.753 回答