8

我有这个脚本可以读取计算机列表并检查计算机是否安装了正确的软件版本。脚本向我回显版本错误的计算机，但我想创建一个日志

Dim strComputer, objFSO, ObjShell, strDisplayName, objList, strObject
Dim objReg, arrSubKeys, strProduct, strVersion, strReqVersion
Const For_Writing = 2
Const ForReading = 1
const ForAppending = 3
Const HKLM        = &H80000002
Const strKeyPath  = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
strReqVersion = "8.2.1 MP2"
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("WScript.Shell")
Set objList = objFSO.OpenTextFile("c:\test\test.txt",ForReading)
Do While Not objList.AtEndOfStream
    strComputer = objList.ReadLine
    If HostOnline(strComputer) = True Then 
       Inventory(strComputer)
    End If 
Loop 
Function Inventory(strComputer)
Set objTextFile = objFSO.OpenTextFile("c:\test\inventory.txt",2,true)
'creating a dictionary object
Set objDictionary = CreateObject("Scripting.Dictionary")
Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _ 
     strComputer & "\root\default:StdRegProv")
     ' Enumerate the subkeys of the Uninstall key
    objReg.EnumKey HKLM, strKeyPath, arrSubKeys
    For Each strProduct In arrSubKeys
  ' Get the product's display name
        objReg.GetStringValue HKLM, strKeyPath & "\" & strProduct, "DisplayName", strDisplayName
  ' Process only products whose name contain 'symantec'
        If InStr(1, strDisplayName, "Symantec", vbTextCompare) > 0 Then
    ' Get the product's display version
        objReg.GetStringValue HKLM, strKeyPath & "\" & strProduct, "DisplayVersion", strVersion
        If strReqVersion <> strVersion Then
            WScript.Echo strObject
            objDictionary.Add strComputer, strVersion
            For Each strObject In objDictionary
             WScript.Echo strObject

             objTextFile.WriteLine(strObject)
            Next   
            objTextFile.Close               
         End If    
        End If  
    Next
End Function
Function HostOnline(strComputername)
'---------- Test to see if host or url alive through ping -----------------
' Returns True if Host responds to ping
' 
' strComputername is a hostname or IP 
    Const OpenAsASCII = 0 
     Const FailIfNotExist = 0 
     Const ForReading =  1 
     Dim objShell, objFSO, sTempFile, fFile 
    Set objShell = CreateObject("WScript.Shell") 
     Set objFSO = CreateObject("Scripting.FileSystemObject") 
    sTempFile = objFSO.GetSpecialFolder(2).ShortPath & "\" & objFSO.GetTempName 
    objShell.Run "cmd /c ping -n 2 -l 8 " & strComputername & ">" & sTempFile, 0 , True 
    Set fFile = objFSO.OpenTextFile(sTempFile, ForReading, FailIfNotExist, OpenAsASCII) 
    Select Case InStr(fFile.ReadAll, "TTL=") 
         Case 0
            HostOnline = False 
         Case Else
            HostOnline = True 
    End Select 
    ffile.close 
     objFSO.DeleteFile(sTempFile)
    Set objFSO = Nothing
    Set objShell = Nothing
End Function

有人可以帮我吗谢谢

4

2 回答 2

19

有几种方法可以做到这一点。最简单的方法是在不修改脚本的情况下使用cscript.exe（在命令提示符中）调用脚本并将输出重定向到文件：

cscript your.vbs > output.log

但是，如果您希望即使用户双击您的脚本也能创建日志，您必须更改您的脚本，以便它写入文件而不是回显输出。打开脚本开头的日志文件：

Set myLog = objFSO.OpenTextFile("C:\my.log", For_Writing, True)

替换WScript.Echo ...为myLog.WriteLine ...，并在退出脚本之前关闭文件：

myLog.Close

一种更复杂的方法是创建一组日志记录函数，这将允许您根据特定条件创建日志行，例如LogInfo()信息性日志消息和LogError()错误。

无耻插件：前段时间我厌倦了一遍又一遍地编写相同的样板日志记录函数，所以我写了一个记录器类，它封装了常用的日志记录工具（交互式控制台、文件、事件日志）并提供了 4 个日志级别的日志记录方法（错误、警告、信息、调试）。该类可用于记录到这样的文件：

Set myLog = New CLogger
myLog.LogToConsole = False
myLog.LogFile = "C:\my.log"

myLog.LogInfo "info message"
...
myLog.LogError "an error occurred"

释放对象时会自动关闭日志文件。

于 2013-04-09T17:37:00.227 回答
3

为什么不使用系统的事件日志？我在这个答案中描述了如何

这意味着大部分工作已为您完成，您无需担心将日志文件放在哪里

于 2014-01-03T07:12:06.657 回答