2

我需要一些 XSLT 语句，它给了我类似“LEFT JOIN”的东西：如果选定的节点确实存在，则返回所有这样的节点，否则只循环一次。

这与 xsl:for-each 循环不同，因为当没有这样的节点时，for-each 循环返回零行。

这是一个实际的例子。

XML 文件：

<root>
    <sec1>
        <x1/> ... <x1/>
    </sec1>
    <sec2>
        <x2/> ... <x2/>
    </sec2>
    ...
    <sec10>
        <x10/> ... <x10/>
    </sec10>
</root>

现在，我不知道我有多少个“x1”、“x2”、..“x10”，我想打印出所有可能的组合。一个简单而错误的解决方案：

<xsl:for-each select="/root/sec1/x1">
    <xsl:for-each select="/root/sec2/x2">
        ...
        <xsl:for-each select="/root/sec10/x10">
           ...print x1 and x2... and x10
        </xsl:for-each>
        ...
    </xsl:for-each>
</xsl:for-each>

这个解决方案是错误的，因为如果没有“x3”，它会返回 0 行（就像 FULL JOIN 一样），而我想查看所有其他值（如 LEFT 或 RIGHT JOIN）。

我可以使用 xsl:choose、xls:when、xsl:foreach 和 xsl:otherwise 的组合，但这很长。

我尝试构建自己的 xsl 模板，但它不起作用：

<xsl:template name="left-join">
    <xsl:param name="select"/>
    <xsl:param name="template"/>

    <xsl:choose>
        <xsl:when test="$select">
            <xsl:for-each select="$select">
                <xsl:call-template name="$templatename"> <!--WRONG -->
                    <xsl:with-param name="one-parameter" select="$select"/>
                </xsl:call-template>
            </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
            <xsl:call-template name="$templatename">
                <xsl:with-param name="one-parameter" select="$select"/>
            </xsl:call-template>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
4

2 回答 2

2

即使我不完全理解您的问题，我也会尝试回答。我的理解是，您正在锁定诸如 sql left join 之类的东西。（例如http://www.w3schools.com/sql/sql_join_left.asp） XML/XSLT 版本可能如下。

输入数据：

    <root>
        <Persons>
            <Person id="1">
                <Name>Hansen</Name>
            </Person>
            <Person id="2">
                <Name>Svendson</Name>
            </Person>
            <Person id="3">
                <Name>Pettersen</Name>
            </Person>
        </Persons>
        <Orders>
            <Order id="1" >
                <P_Id>3</P_Id>
                <OrderNo>77895</OrderNo>
            </Order>
            <Order id="2">
                <P_Id>3</P_Id>
                <OrderNo>44678</OrderNo>
            </Order>
            <Order id="3">
                <P_Id>1</P_Id>
                <OrderNo>22456</OrderNo>
            </Order>
            <Order id="4">
                <P_Id>1</P_Id>
                <OrderNo>24562</OrderNo>
            </Order>
            <Order id="5">
                <P_Id>15</P_Id>
                <OrderNo>34764</OrderNo>
            </Order>
        </Orders>
    </root>

XSLT

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
        <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
        <xsl:strip-space elements="*"/>

        <xsl:template match="root">
            <xsl:call-template name="person_order" />
        </xsl:template>

        <xsl:template name="person_order">
           <orders>
            <xsl:for-each select="//Person">
                <xsl:variable name ="pid" select="@id" />
                <xsl:call-template name="left_join">
                    <xsl:with-param name="jname" select="'order'"/>
                    <xsl:with-param name="left" select="."/>
                    <xsl:with-param name="right" select="//Order[P_Id = $pid]"/>
                </xsl:call-template>
            </xsl:for-each>
           </orders>
        </xsl:template>


        <xsl:template name="left_join">
            <xsl:param name="jname" />
            <xsl:param name="left" />
            <xsl:param name="right" />

            <xsl:choose>
                <xsl:when test="$right">
                    <xsl:for-each select="$right">
                        <xsl:call-template name="print_join">
                            <xsl:with-param name="jname" select="$jname"/>
                            <xsl:with-param name="left" select="$left"/>
                            <xsl:with-param name="right" select="."/>
                        </xsl:call-template>
                    </xsl:for-each>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:call-template name="print_join">
                        <xsl:with-param name="jname" select="$jname"/>
                        <xsl:with-param name="left" select="$left"/>

                    </xsl:call-template>
                </xsl:otherwise>
            </xsl:choose>

        </xsl:template>
        <xsl:template match="node() | @*">
            <xsl:copy>
                <xsl:apply-templates select="node() | @*"/>
            </xsl:copy>
        </xsl:template>

        <xsl:template name="print_join">
            <xsl:param name="jname" />
            <xsl:param name="left" />
            <xsl:param name="right" />
            <xsl:element name="{$jname}" >
                <xsl:for-each select="$left">
                    <xsl:apply-templates select="node() "/>
                </xsl:for-each>
                <xsl:if test="$right">
                    <xsl:for-each select="$right">
                        <xsl:apply-templates select="node() "/>
                    </xsl:for-each>
                </xsl:if>
            </xsl:element>
        </xsl:template>

    </xsl:stylesheet>

生成输出：

    <orders>
      <order>
        <Name>Hansen</Name>
        <P_Id>1</P_Id>
        <OrderNo>22456</OrderNo>
      </order>
      <order>
        <Name>Hansen</Name>
        <P_Id>1</P_Id>
        <OrderNo>24562</OrderNo>
      </order>
      <order>
        <Name>Svendson</Name>
      </order>
      <order>
        <Name>Pettersen</Name>
        <P_Id>3</P_Id>
        <OrderNo>77895</OrderNo>
      </order>
      <order>
        <Name>Pettersen</Name>
        <P_Id>3</P_Id>
        <OrderNo>44678</OrderNo>
      </order>
    </orders>
于 2013-04-10T09:04:05.820 回答
0

使用嵌套的 for-each 执行此操作似乎非常错误：它似乎是递归的候选者。但我很难理解问题的确切性质。x1、x2 等是否每次出现（0 或 1）次？在这种情况下，问题肯定是微不足道的，您不需要 for-each 来迭代单例。

如果您想避免递归、条件代码的冗长，那么是时候迁移到 XSLT 2.0 了。

于 2013-04-09T13:32:53.203 回答