list - 从列表中生成方案中的所有可能性

Question

我有一个子列表列表：

((a b c) (e f) (z h)) 

我想生成这样的东西：

((a e z) (a f z) (a e h) (a f h) (b e z) (b e h) ... ) and so on.

我想，给定一个子列表列表，生成所有可能的子列表，其中包含来自每个输入子列表的元素。

我怎样才能得到这个输出？

Answer 1

您正在描述列表列表的笛卡尔积，这是一个可能的实现（在 Racket 中工作）：

(define (cartesian-product lsts)
  (foldr (lambda (lst acc)
           (for*/list ((x (in-list lst))
                       (y (in-list acc)))
             (cons x y)))
         '(())
         lsts))

现在，如果你不使用 Racket，这里有一个使用标准程序的 vanilla 实现；它应该适用于任何定义类似fold-right- 过程的 Scheme 解释器：

(define (flatmap f lst)
  (apply append (map f lst)))

(define (cartesian-product lsts)
  (foldr (lambda (lst acc)
           (flatmap (lambda (x)
                      (map (lambda (y)
                             (cons x y))
                           acc))
                    lst))
         '(())
         lsts))

无论哪种方式，它都按预期工作：

(cartesian-product '((a b c) (e f) (z h)))

=> '((a e z) (a e h) (a f z) (a f h) (b e z) (b e h)
     (b f z) (b f h) (c e z) (c e h) (c f z) (c f h))