11

我的任务是使用 OCaml 为（玩具）语法编写（玩具）解析器，但不知道如何开始（并继续）这个问题。

这是一个示例 awk 语法：

type ('nonterm, 'term) symbol = N of 'nonterm | T of 'term;;

type awksub_nonterminals = Expr | Term | Lvalue | Incrop | Binop | Num;;

let awksub_grammar =
  (Expr,
   function
     | Expr ->
         [[N Term; N Binop; N Expr];
          [N Term]]
     | Term ->
     [[N Num];
      [N Lvalue];
      [N Incrop; N Lvalue];
      [N Lvalue; N Incrop];
      [T"("; N Expr; T")"]]
     | Lvalue ->
     [[T"$"; N Expr]]
     | Incrop ->
     [[T"++"];
      [T"--"]]
     | Binop ->
     [[T"+"];
      [T"-"]]
     | Num ->
     [[T"0"]; [T"1"]; [T"2"]; [T"3"]; [T"4"];
      [T"5"]; [T"6"]; [T"7"]; [T"8"]; [T"9"]]);;

这里有一些要解析的片段：

let frag1 = ["4"; "+"; "3"];;
let frag2 = ["9"; "+"; "$"; "1"; "+"];;

我正在寻找的是一个规则列表，它是解析片段的结果，例如 frag1 ["4"; "+"; “3”]：

 [(Expr, [N Term; N Binop; N Expr]);
  (Term, [N Num]);
  (Num, [T "3"]);
  (Binop, [T "+"]);
  (Expr, [N Term]);
  (Term, [N Num]);
  (Num, [T "4"])]

限制是不要使用除 List... 之外的任何 OCaml 库：/

4

3 回答 3

13

这是一个粗略的草图 - 直接进入语法并按顺序尝试每个分支。可能的优化：分支中单个非终端的尾递归。

exception Backtrack

let parse l =
  let rules = snd awksub_grammar in
  let rec descend gram l =
    let rec loop = function 
      | [] -> raise Backtrack
      | x::xs -> try attempt x l with Backtrack -> loop xs
    in
    loop (rules gram)
  and attempt branch (path,tokens) =
    match branch, tokens with
    | T x :: branch' , h::tokens' when h = x -> 
        attempt branch' ((T x :: path),tokens')
    | N n :: branch' , _ -> 
        let (path',tokens) = descend n ((N n :: path),tokens) in 
        attempt branch' (path', tokens)
    | [], _ -> path,tokens
    | _, _ -> raise Backtrack
  in
  let (path,tail) = descend (fst awksub_grammar) ([],l) in
  tail, List.rev path
于 2009-10-21T07:56:01.350 回答
9

好的，所以首先你应该做的是编写一个词法分析器。这是接受“原始”输入的函数，例如["3"; "-"; "("; "4"; "+"; "2"; ")"]，并将其拆分为标记列表（即终端符号的表示）。

您可以将令牌定义为

type token =
    | TokInt of int         (* an integer *)
    | TokBinOp of binop     (* a binary operator *)
    | TokOParen             (* an opening parenthesis *) 
    | TokCParen             (* a closing parenthesis *)     
and binop = Plus | Minus

lexer函数的类型string list -> token list和输出

lexer ["3"; "-"; "("; "4"; "+"; "2"; ")"]

会是这样的

[   TokInt 3; TokBinOp Minus; TokOParen; TokInt 4;
    TBinOp Plus; TokInt 2; TokCParen   ]

这将使编写解析器的工作更容易，因为您不必担心识别什么是整数、什么是运算符等。

这是第一步，不是太难，因为令牌已经分开了。词法分析器所要做的就是识别它们。

完成此操作后，您可以编写一个更现实的词法分析器，类型为string -> token list，它接受实际的原始输入，例如"3-(4+2)"并将其转换为令牌列表。

于 2009-10-19T15:32:51.247 回答
3

我不确定您是否特别需要派生树，或者这只是解析的第一步。我假设后者。

您可以通过定义类型来定义生成的抽象语法树的结构。它可能是这样的：

type expr =
    | Operation of term * binop * term
    | Term of term
and term =
    | Num of num
    | Lvalue of expr
    | Incrop of incrop * expression
and incrop = Incr | Decr
and binop = Plus | Minus
and num = int

然后我会实现一个递归下降解析器。当然，如果您可以streams与预处理器结合使用会更好camlp4of......

顺便说一句，这里的 OCaml 文档中有一个关于算术表达式的小示例。

于 2009-10-18T21:54:53.480 回答