1

我需要接收 1 个 .XML 文件，并输出 N 个作为输入文件子集的文件。该子集基于 2 个节点的谓词检查。我的计划是在 XSLT 模板上运行输入文件 N 次以输出每个文件。

我的输入如下所示：

<employee_data>
<employees>
    <employee id="1">
    <first_name>2sk8d</first_name>      
    <agency_code>38</agency_code>
    <offices_administered>
        <office_administered office_identifier="ALLPOIs" agency_code="HL" />
    </offices_administered>
    </employee>
    <employee id="2">
        <first_name>2sk8d</first_name>
        <agency_code>24</agency_code>
        <offices_administered>
            <office_administered office_identifier="ALLPOIs" agency_code="22" />
        </offices_administered>
    </employee>
    <employee id="3">
        <first_name>2sk8d</first_name>
        <agency_code>22</agency_code>
        <offices_administered>
            <office_administered office_identifier="ALLPOIs" agency_code="HL" />
        </offices_administered>
    </employee>     
</employees>

我的 XSLT 看起来像这样

<?xml version="1.0" encoding="utf-8"?>


<xsl:output method="xml" indent="yes"  encoding="utf-16"/>                

<xsl:template match="/employee_data/employees/employee[agency_code='22' or offices_administered/office_administered/@agency_code='22']">        
    <xsl:copy>
        <xsl:copy-of select="."/>
        <xsl:apply-templates/>
    </xsl:copy>         
</xsl:template>

<xsl:template match="@* | node()">
    <xsl:message terminate="no">
        Catch 1 <xsl:value-of select="name()"/>
    </xsl:message>
</xsl:template>

我的问题是我的输出不包含 EmployeeData 或 Employees 根/父节点。

如果我将 xslt 更改为放入第一个 xsl:template-match，那么这些标签会重复多次/

如果我将匹配谓词更改为 /employee_data/employees[employee/agency_code='22' 或 employee/offices_administered/office_administered/@agency_code='22'] 那么我会得到所有员工。

这几乎就像我想要一些魔法来将我的整个比赛输出包装在我的两个父标签中。

4

1 回答 1

0

根据我从这个问题的理解，你想要这样的东西：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/">
   <employee_data>
        <employees>

          <xsl:apply-templates select=
          "/*/employees/employee
                [agency_code='22'
                or offices_administered/office_administered/@agency_code='22']"/>
        </employees>
  </employee_data>
 </xsl:template>

  <xsl:template match="employee">
   <xsl:copy-of select="."/>
  </xsl:template>

  <xsl:template match="@* | node()">
    <xsl:message terminate="no">
        Catch 1 <xsl:value-of select="name()"/>
    </xsl:message>
  </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<employee_data>
    <employees>
        <employee id="1">
            <first_name>2sk8d</first_name>
            <agency_code>38</agency_code>
            <offices_administered>
                <office_administered office_identifier="ALLPOIs" agency_code="HL" />
            </offices_administered>
        </employee>
        <employee id="2">
            <first_name>2sk8d</first_name>
            <agency_code>24</agency_code>
            <offices_administered>
                <office_administered office_identifier="ALLPOIs" agency_code="22" />
            </offices_administered>
        </employee>
        <employee id="3">
            <first_name>2sk8d</first_name>
            <agency_code>22</agency_code>
            <offices_administered>
                <office_administered office_identifier="ALLPOIs" agency_code="HL" />
            </offices_administered>
        </employee>
    </employees>
</employee_data>

产生了想要的正确结果：

<employee_data>
   <employees>
      <employee id="2">
         <first_name>2sk8d</first_name>
         <agency_code>24</agency_code>
         <offices_administered>
            <office_administered office_identifier="ALLPOIs" agency_code="22"/>
         </offices_administered>
      </employee>
      <employee id="3">
         <first_name>2sk8d</first_name>
         <agency_code>22</agency_code>
         <offices_administered>
            <office_administered office_identifier="ALLPOIs" agency_code="HL"/>
         </offices_administered>
      </employee>
   </employees>
</employee_data>

二、XSLT 2.0 解决方案

使用 XSLT 2.0 可以通过一次转换运行创建所有 N 个文档：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pCodes" as="xs:string+" select="'22', '38'"/>
 <xsl:variable name="vDoc" select="/"/>

 <xsl:template match="/">
   <xsl:for-each select="$pCodes">
    <xsl:variable name="vCode" select="."/>
    <xsl:result-document href="'Agency'{.}.xml">
       <employee_data>
             <employees>

              <xsl:apply-templates select=
              "$vDoc/*/employees/employee
                    [agency_code=$vCode
                    or offices_administered/office_administered
                                              /@agency_code=$vCode]"/>
             </employees>
       </employee_data>
      </xsl:result-document>
  </xsl:for-each>
 </xsl:template>

  <xsl:template match="employee">
   <xsl:copy-of select="."/>
  </xsl:template>

  <xsl:template match="@* | node()">
    <xsl:message terminate="no">
        Catch 1 <xsl:value-of select="name()"/>
    </xsl:message>
  </xsl:template>
</xsl:stylesheet>

当我们在同一个提供的（上面的）XML 文档上运行这个转换时，会创建两个文件：

Saxon 9.1.0.5J from Saxonica
Java version 1.6.0_31
Stylesheet compilation time: 610 milliseconds
Processing file:/C:/Program%20Files/Java/jre6/bin/marrowtr.xml
Building tree for file:/C:/Program%20Files/Java/jre6/bin/marrowtr.xml using class net.sf.saxon.tinytree.TinyBuilder
Tree built in 0 milliseconds
Tree size: 25 nodes, 21 characters, 9 attributes
Loading net.sf.saxon.event.MessageEmitter

Writing to file:/C:/Program%20Files/Java/jre6/bin/'Agency'22.xml
Writing to file:/C:/Program%20Files/Java/jre6/bin/'Agency'38.xml

Execution time: 94 milliseconds
Memory used: 11464160
NamePool contents: 26 entries in 26 chains. 6 prefixes, 7 URIs
于 2013-04-05T03:07:50.497 回答