1

我有一个datetimes.log包含数十万个时间戳的日志文件 ()，格式如下：

YYYY-MM-DD HH:mm:ss

例如：

2013-03-28 06:43:51
2013-03-28 06:43:55
2013-03-28 06:44:03
...etc.

我想编写一个简单的 Perl 脚本来输出一个unix_timestamps.log包含相同条目的新文件，但不是日期时间，而是具有相应的 UNIX 纪元时间戳。对于上面的示例，该unix_timestamps.log文件将包含以下信息：

1364453031
1364453035
1364453043
...etc.

我唯一能想到的是perl convert_2_timestamps.pl：

#!/usr/bin/perl

use warnings;
use strict;

grep m/_(\d{4})(\d\d)(\d\d)/ | POSIX::mktime(?, ?, ?, ?, ?, ?) > unix_timestamps.log

但不确定如何将参数转换为mktime，也不确定这是否是正确的方法。提前致谢。

4

4 回答 4

4 
use strict;
use warnings;
use DateTime::Format::Strptime;


my $parser = DateTime::Format::Strptime->new(
  pattern => '%Y-%m-%d %H:%M:%S',
  on_error => 'croak',
);

while( <DATA> ) {
   my $dt = $parser->parse_datetime($_);
   print $dt->epoch, "\n";
}

__DATA__
2013-03-28 06:43:51
2013-03-28 06:43:55
2013-03-28 06:44:03
于 2013-04-03T20:39:23.567 回答
2

这是Time::Piece模块的完美使用，它已经成为 Perl 发行版的标准部分超过五年了。

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

use Time::Piece;

# Read the data a record at a time. Data ends up in $_.
# N.B. Using built-in DATA filehandle for this demo.
#      In the real world you'd open a separate filehandle.
while (<DATA>) {
  chomp;
  # Create a Time::Piece object using strptime (that's "string
  # parse time") and immediately call the epoch method on the
  # new object to get the value you want.
  say Time::Piece->strptime($_, '%Y-%m-%d %H:%M:%S')->epoch;
}

__DATA__
2013-03-28 06:43:51
2013-03-28 06:43:55
2013-03-28 06:44:03
于 2013-04-04T09:51:43.053 回答
0

试试Date::ParseCPAN 模块。( http://metacpan.org/pod/Date::Parse )

有了它，您convert_2_timestamps.pl可以：

#!/usr/bin/perl

use warnings;
use strict;

use Date::Parse;

while (<>) {
  chomp;
  printf("%s\n", str2time("$_ GMT"));
}

请注意，我必须将 GMT 附加到您的示例输入中才能获得预期的输出。

运行为：

perl convert_2_timestamps.pl < datetimes.log > unix_timestamps.log
于 2013-04-03T20:29:48.213 回答
0

您可以像这样分解 YYYY-MM-DD HH:mm:ss 格式：

my ( $y, $m, @t ) = split /[-: ]+/, $time_str;
my $time = mktime( reverse @t, $m - 1, $y - 1900 );

但你也可以像这样把它放在一个替换中：

s{(\d{4})-(0?[1-9]\d?)-(0?[1-9]\d?) (0?\d{1,2}):(0?\d{1,2}):(0?\d{1,2})}{
    mktime( $6, $5, $4, $3, $2 - 1, $1 - 1900 )
 }e;
于 2013-04-03T21:03:10.083 回答