1

我正在尝试编写一个宏来查看一系列时间，将每个时间与基准时间进行比较，然后在每个比较时间旁边生成一个注释。当我运行宏时，它将对范围内的第一个单元格执行此操作，但不会对其余单元格执行此操作。

“ActivityData”工作表中的单元格 C8 是基准时间。要比较的时间从“SIS”工作表的单元格 F12 开始，数量不同。

这是完整的代码：

Sub TimeCalc()

Dim wb As Workbook
Dim SIS As Worksheet
Dim Act As Worksheet

Set wb = ActiveWorkbook
Set SIS = wb.Worksheets("SIS")
Set Act = wb.Worksheets("ActivityData")

'Navigate to start times
wb.Worksheets("SIS").Select
Range("f12").Select
SIS.Range(Selection, Selection.End(xlDown)).Select

'Compare start times
For Each rng In Selection
If Act.Range("C8").Value < rng.Value Then
    ActiveCell.Offset(0, -1).Range("A1").Value = "Missed " & Format(Act.Range("c8").Value, "Medium time") & " - " & Format((rng.Value - 0.000694444), "Medium Time")
    Else
    End If
    On Error Resume Next
    Next rng

End Sub

谢谢你的帮助！

4

2 回答 2

1

假设您要将结果放在正在检查的数据左侧的列中：

Option Explicit

Sub TimeCalc()

    Dim wb As Workbook
    Dim SIS As Worksheet
    Dim Act As Worksheet
    Dim myBaseLineRng As Range
    Dim compareRng As Range
    Dim Rng As Range

    On Error GoTo 0

    Set wb = ActiveWorkbook
    Set SIS = wb.Worksheets("SIS")
    Set Act = wb.Worksheets("ActivityData")
    Set myBaseLineRng = Act.Range("C8")
    Set compareRng = SIS.Range(SIS.Range("F12"), SIS.Range("F12").End(xlDown))

    'Compare start times
    For Each Rng In compareRng.Cells
        If myBaseLineRng.Value < Rng.Value Then
            Rng.Offset(0, -1).Value = "Missed " & Format(myBaseLineRng.Value, "Medium time") & " - " & Format((Rng.Value - 0.000694444), "Medium Time")
        End If
    Next Rng

End Sub
于 2013-04-03T15:34:36.303 回答
0

您只是将基准列表中的值与活动列表中的第一个值进行比较，如 If 语句中所示。如果我正确理解您的问题，您将需要遍历您的活动列表以检查每一行

即循环遍历活动列表对于活动列表中的每个值循环遍历您的基准时间以检查活动列表中的下一个值。

除非我误解了你的问题。

于 2013-04-03T15:29:43.527 回答