sql - Oracle 使用 REGEXP 验证日期字段

Question

我正在使用 Oracle 11G，并且我有一个日期列（Var char 2），其中日期是手动输入到数据库中的，不幸的是，很多时候输入的日期无效。我只想使用某种 REGEXP LIKE 语句选择有效的日期字段。以下是我想选择的可能的有效格式。

DATE

JULY 31, 2009
7/31/2009
31-JUL-09

任何不在这 3 种可能格式中的东西我都不想选择。有人可以帮我想出一个 REGEXP 或其他方式来选择这些有效的日期格式。提前致谢。

Answer 1

尝试 PL/SQL 而不是正则表达式。它会明显变慢，但会更安全，更容易维护和扩展。您应该依靠 Oracle 格式模型来正确执行此操作。我已经看到很多尝试使用正则表达式验证此信息，但我很少看到它正确完成。

如果您真的关心性能，那么真正的答案是修复您的数据模型。

代码和测试用例：

--Function to convert a string to a date, or return null if the format is wrong.
create or replace function validate_date(p_string in string) return date is
begin
    return to_date(p_string, 'MONTH DD, YYYY');
exception when others then
    begin
        return to_date(p_string, 'MM/DD/YYYY');
    exception when others then
        begin
            return to_date(p_string, 'DD-MON-RR');
        exception when others then
            return null;
        end;
    end;
end;
/

--Test individual values
select validate_date('JULY 31, 2009') from dual;
2009-07-31
select validate_date('7/31/2009') from dual;
2009-07-31
select validate_date('31-JUL-09') from dual;
2009-07-31
select validate_date('2009-07-31') from dual;
<null>

简单的性能测试：

--Create table to hold test data
create table test1(a_date varchar2(1000)) nologging;

--Insert 10 million rows
begin
    for i in 1 .. 100 loop
        insert /*+ append */ into test1
        select to_char(sysdate+level, 'MM/DD/YYYY') from dual connect by level <= 100000;

        commit;
    end loop;
end;
/

--"Warm up" the database, run this a few times, see how long a count takes.
--Best case time to count: 2.3 seconds
select count(*) from test1;


--How long does it take to convert all those strings?
--6 minutes... ouch
select count(*)
from test1
where validate_date(a_date) is not null;