3

我在 Delphi 7 应用程序（CLX）中遇到了内存泄漏问题，代码如下：

unit Unit2;

interface

  uses ECRClass, ECR_Text,  SysUtils, Types, Classes, Variants, Math;

  type tLeakClass = class
  private
  fsType : integer;

  public
  fsPrinter : TECR_Class;

  published
  constructor Create (AOwner : TComponent);
  destructor Destroy();
  end;


implementation

   constructor tLeakClass.Create (AOwner : TComponent);
   begin
   fsPrinter := TECR_Text.Create(AOwner);
   end;

   destructor tLeakClass.Destroy();
   begin
     fsPrinter.Free
   end;

end.

fsPrinter即使在主窗体（TForm）关闭时释放对象结果也会泄漏：

unit Unit1;

interface

uses
  SysUtils, Types, Classes, Variants, QTypes, QGraphics, QControls, QForms, 
  QDialogs, QStdCtrls, Unit2;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    tleak : tLeakClass;
  end;

var
  Form1: TForm1;

implementation

{$R *.xfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
     tLeak := tLeakClass.Create(Self);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
   tleak.Free
end;

end.

这是 FastMM4 的泄漏报告：

A memory block has been leaked. The size is: 740

This block was allocated by thread 0xBA8, and the stack trace (return addresses) at the time was:
402F1C [system.pas][System][@GetMem][2439]
403C77 [system.pas][System][TObject.NewInstance][8360]
404012 [system.pas][System][@ClassCreate][9019]
502F15 [ECR_Text.pas][ECR_Text][TECR_Text.Create][101]
403C80 [system.pas][System][TObject.NewInstance][8360]
404012 [system.pas][System][@ClassCreate][9019]
5030C6 [Unit2.pas][Unit2][tLeakClass.Create][24]
43856C [QStdCtrls.pas][QStdCtrls][2863]
503300 [Unit1.pas][Unit1][TForm1.Button1Click][30]
447076 [QControls.pas][QControls][TControl.Click][1977]
43858C [QStdCtrls.pas][QStdCtrls][TButton.Click][2871]

The block is currently used for an object of class: TECR_Text

在这里，您可以下载代表问题的项目的完整SSCCE示例（单击按钮运行示例并关闭表单）。

为什么fsPrinter对象泄漏？我怎样才能避免泄漏？

4

1 回答 1

6

您的析构函数声明不正确。你写了：

destructor Destroy();

但是你必须重写在TObject. 如果你不这样做，那么你的析构函数将不会被调用，Free它会调用在 中声明的虚拟析构函数TObject。

像这样修复它：

destructor Destroy(); override;

尽管在这种情况下并不重要，但您应该养成在构造函数和析构函数中调用继承的构造函数和析构函数的习惯。这样，当您从一个比TObject其构造函数和析构函数执行更多操作的类派生时，您将确保超类代码运行。

constructor tLeakClass.Create (AOwner : TComponent);
begin
  inherited Create;
  fsPrinter := TECR_Text.Create(AOwner);
end;

destructor tLeakClass.Destroy();
begin
  fsPrinter.Free;
  inherited;
end;

不过 FastMM 报告有点奇怪。它报告该TECR_Text对象已泄漏。但是由于您创建了该表单所拥有的内容，因此表单应该将其删除。问题代码中明显泄露的对象是tLeakClass

所以我怀疑课程中还有其他我们看不到的问题。很可能你犯了同样的错误并省略了override我们看不到的类的析构函数。

于 2013-03-31T15:40:32.617 回答