6

我正在尝试在 XSLT 中使用增量。并将输出写入txt文件。这是我的代码： Xslt 代码：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
    <xsl:output method="text"/>
    <xsl:result-document href="foo.txt" method=text />
    <xsl:template match="/">
    </xsl:template>

  <xsl:template match="/build/build">
    <xsl:variable name="buildNumber" select="."/>
    <xsl:element name="build">
      <xsl:value-of select="$buildNumber + 1"/>
    </xsl:element>
  </xsl:template>

  <xsl:template match="/|@*|node()">
    <xsl:value-of select="build/major"/>
    <xsl:value-of select="build/minor"/>
    <xsl:value-of select="build/build"/>
    <xsl:value-of select="build/release"/>
      <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>  
  </xsl:template>
</xsl:stylesheet>

XML 代码是：

 <?xml version="1.0" encoding="utf-8"?>
    <?xml-stylesheet type="text/xsl" href="E:\Build\genVer.xsl"?>
    <build>
        <major>1.</major><minor>0.</minor><build>0</build><release>.0</release>
    </build>

我尝试使用<xsl:result-document>它给出了错误，说<xsl:result-document>不能是<xsl:stylesheet>or的子级<xsl:template>。谢谢

4

2 回答 2

10

您的方法<xsl:result-document>非常合理。唯一的问题是您的样式表是 XSLT 1，而<xsl:result-document>您需要 XSLT 2。XSLT 作为一种函数式语言与这个问题无关。

如有必要，请发布您使用的 XSLT 代码，<xsl:result-document>我会为您修复它。

编辑：

在这里，您的代码进行了必要的更改。部分原始代码，例如method="text"表明您希望结果是文本文件，而<xsl:element>看起来您正在尝试输出 XML 文件，所以我为两者编写了代码。如前所述，<xsl:result-document>需要 XSLT 2。

这将创建一个 XML 文件：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml"/>

   <xsl:template match="/">
      <xsl:variable name="foldername" select="concat(/build/major, /build/minor, string(/build/build + 1), build/release)"/>
      <xsl:result-document href="{$foldername}/foo.xml" method="xml">
         <xsl:copy>
            <xsl:apply-templates/>
         </xsl:copy>
      </xsl:result-document>
   </xsl:template>

   <xsl:template match="element()">
      <xsl:copy>
         <xsl:apply-templates/>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="/build/build">
      <xsl:copy>
         <xsl:variable name="buildNumber" select="."/>
         <xsl:value-of select="$buildNumber + 1"/>
      </xsl:copy>
   </xsl:template>

</xsl:stylesheet>

这将创建一个文本文件：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text"/>

   <xsl:template match="/">
      <xsl:variable name="foldername" select="concat(/build/major, /build/minor, string(/build/build + 1), build/release)"/>
      <xsl:result-document href="{$foldername}/foo.txt" method="text">
         <xsl:apply-templates/>
      </xsl:result-document>
   </xsl:template>

   <xsl:template match="element()">
      <xsl:apply-templates/>
   </xsl:template>

   <xsl:template match="/build/build">
      <xsl:variable name="buildNumber" select="."/>
      <xsl:value-of select="$buildNumber + 1"/>
   </xsl:template>

</xsl:stylesheet>

如您所愿，输出文件在名称为版本的文件夹中创建，但请注意该文件夹必须事先存在。

于 2013-03-29T16:44:22.257 回答
0

在我的环境中不支持 XSLT 2.0，所以我想出了以下解决方法：

#!/usr/bin/zsh

. =(xsltproc =(<<'XSLT_'
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="text"/>
   <xsl:strip-space elements="*"/>

<xsl:template match="/SummitFTMonitor/messages">
  <xsl:variable name="key" select="Key/text()"/>

<![CDATA[cat <<'IJEBVNKCEUJGHKLO' > ]]><xsl:value-of select="$key"/>_response.xml
<xsl:value-of select="Response"/>
IJEBVNKCEUJGHKLO

</xsl:template>
</xsl:stylesheet>
XSLT_) $*)

基本上，在这个 zsh 脚本中，XSLT 用于生成如下语句

cat <<'XXXXX' > file_name
the value of nodes, etc ....
XXXXX

然后这些语句由 zsh 获取，从而创建文件。

于 2017-06-20T12:02:06.430 回答