vba - 将传入消息的附件添加到新的传出消息

Question

我有一份每周通过电子邮件发送几次的订单，其中包含我需要发送以进行处理的附件。处理文件的软件要求电子邮件正文中没有签名和文本。

我通过查找发件人和附件的规则触发脚本。该脚本应该抓取一个模板并插入附件。我遇到的问题是插入附件。

这是我到目前为止所拥有的。感谢您的帮助。

Sub SendLeadOrder(Item As Outlook.MailItem)

    Set objMsg = Application.CreateItemFromTemplate("C:\OrderTemplate.oft")

    objMsg.Attachments.Add Item.Attachments
    objMsg.Display
    'objMsg.Send

End Sub

Answer 1

我很确定您需要将附件保存到磁盘，然后将它们重新应用到新邮件中。像这样

Dim Item As Outlook.MailItem
Dim objMsg As Outlook.MailItem
Dim objAtt As Outlook.Attachment
Dim sPath As String

Set Item = ActiveInspector.currentItem
Set objMsg = Application.CreateItemFromTemplate("C:\OrderTemplate.oft")

For Each objAtt In Item.Attachments
    sPath = Environ("TEMP") & "\" & objAtt.FileName
    objAtt.SaveAsFile sPath
    objMsg.Attachments.Add sPath
Next objAtt

objMsg.Display

您确定仅转发消息并根据需要进行清理并不容易吗？像这样

Dim Item As Outlook.MailItem
Dim objMsg As Outlook.MailItem

Set Item = ActiveInspector.currentItem
Set objMsg = Item.Forward
With objMsg
    .To = "someone@example.com"
    .Subject = "Predifined Subject"
    .Body = vbNullString
    .Display
End With