5

我认为这是 F# 的一个众所周知的限制，但我找不到任何好的解决方法……</p>

所以，这里是代码（我试图让它尽可能简单，所以它可能看起来没有任何意义）：

[<ReflectedDefinition>]
type Human (makeAName: unit -> string) as self =
    let mutable cats : Cat array = [| |]
    do
        // get a cat
        cats <- Array.append cats [| new Cat (self, makeAName ()) |]
    member this.Cats = cats
and
 [<ReflectedDefinition>]
 Cat (owner : Human, name : string) = class end

编译器说：

错误 FS0452：引号不能包含数组上的内联汇编代码或模式匹配

实际上as self，破坏一切的是数组属性 getter 的组合。

这里的要点是：

  • 我真的很想使用数组，因为我希望 WebSharper 将我的集合转换为 JavaSript 数组。
  • 我真的需要构造函数中的自我标识符。
  • 我真的需要类（即功能样式不起作用）。
  • 每个方法的自标识符 ( member this.Foo) 工作正常。

我能想到的一种解决方法是将构造函数设为私有并使用静态方法来构造对象。这样我就不需要了as self。但这只是愚蠢的。

有没有更好的选择？

更新：

这是一个更简单的例子：

[<ReflectedDefinition>]
type User (uid: int) as self =
    let ROOT_UID = 0
    member this.isRoot = (uid = ROOT_UID)

我as self什至不能定义一个类常量。好吧，这实际上是一个单独的问题，但我会在这里问：在这种特殊情况下如何定义类常量？

4

1 回答 1

8

我不认为这很愚蠢。为了清晰起见，我们实际上更喜欢静态构造函数方法，即使在不使用 WebSharper 的代码中也是如此。在整个 IntelliFactory 代码库中，我们很少使用self.

您遇到了 F# 编译器和引用的两个恼人的限制。正如您所指出的，静态方法可以解决self问题：

[<ReflectedDefinition>]
type Human private (cats: ref<Cat []>) =
    member this.Cats = !cats

    static member Create(makeAName: unit -> string) =
        let cats = ref [| |]
        let h = Human(cats)
        let cat = Cat(h, makeAName())
        cats := [| cat |]
        h

and [<ReflectedDefinition>] Cat (owner: Human, name: string) =
    class
    end

还有许多其他方法可以实现这一点，例如您可以摆脱ref间接性。

其次，你经常会得到带有数组操作FS0452的代码，即使是在普通的静态方法中也是如此。ReflectedDefinition这通常可以通过使用库函数而不是直接数组访问 ( Array.iter, Array.map) 来解决。

对于第二个例子，你真的想要这个：

[<ReflectedDefinition>]
module Users =

    [<Literal>]     
    let ROOT_UID = 0

    type User(uid: int) =
        member this.isRoot = (uid = ROOT_UID)

注释将[<Literal>]让您对常量进行模式匹配，如果有多个常量，这会很方便。

对于您的积分：

  1. 我真的很想使用数组——应该没问题
  2. 我真的需要一个自我标识符——从来没有必要，就像构造函数不是一样
  3. 我真的需要类（即功能样式不起作用） - 绝对不是真的
  4. 每个方法的自标识符（成员 this.Foo）工作正常 - 是的，并且很有用
于 2013-03-28T11:58:34.530 回答